1 REM ASTRO 3.3 (C) LOGI'STICK 84
2 GOSUB452:FSET1500:DEFFNAD(X)=PEEK(X+1)*256+PEEK(X):TP=FNAD(&H210)-600:CLEAR1500,TP
3 DEFFNAD(X)=PEEK(X+1)*256+PEEK(X):AD=FNAD(&H1DF)+12
4 DEFFNF(D)=D-360*INT(D/360):U$="££££.£":PI=3.141592:Z=180/PI:Y=36525
5 ONERRORGOTO440
6 INIT£1,"A.PARM"
7 GOSUB112
8 GOSUB156
9 GOSUB208
10 GOSUB277
11 GOSUB313
12 GOSUB378
13 INIT£1,"A.PARM":INPUT£1,A%,B%,C%:B%=B%+1:PRINT£1,A%,B%,C%
14 LPRINT°1,0§"(C) LOGI'STICK 84"
15 LPRINTTAB(50);"le ";MID$(DATE$,7,2);MID$(DATE$,3,4);MID$(DATE$,1,2)
16 LPRINT"Programme 'ASTRO' Version 3.3"
17 PRINT "Sauvegarde No"F$:PRINT N$;PR$;"(5 Enr.)";:GOTO22
18 L$=RIGHT$(STR$(INT(XX*100)),LEN(STR$(INT(XX*100)))-1)
19 IFLEN(L$)>5THENL$="00000"ELSEL$=STRING$(5-LEN(L$),"0")+L$
20 IFXX<0THENL$="-"+RIGHT$(L$,4)
21 VR$=VR$+L$:RETURN
22 VR$="":FORI=0TO11:XX=C!(I):GOSUB18:NEXTI:GOSUB151:PRINT"1";
23 INIT£2,"CASO:":PRINT£2,DD$+FNY$(10,NJ)+FNY$(6,LC)+FNY$(6,TL)+VR$
24 VR$="":FORI=0TO9:XX=R!(I):GOSUB18:NEXTI:VR$=VR$+","
25 FORI=0TO9:XX=H!(I):GOSUB18:NEXTI:VR$=VR$+","
26 FORI=0TO9:XX=G!(I):GOSUB18:NEXTI:VR$=VR$+","
27 FORI=0TO9:XX=L!(I):GOSUB18:NEXTI:PRINT "2";:N=3:PRINT£2,VR$
28 FORJ=ADTOAD+440STEP147:VR$="":FORI%=JTOJ+146:VR$=VR$+CHR$(PEEK(I%)+32)
29 NEXTI%:PRINTN;:N=N+1:PRINT£2,VR$:NEXTJ
30 GOTO1
31 DATA 12,31,33,41,58,63,65,114,116,116,255,12,42,55,55,59,61,65,113,255
32 DATA 13,37,55,55,60,110,255,14,38,54,54,56,56,59,110,255
33 DATA 15,38,56,56,58,110,255,16,38,57,108,110,110,255
34 DATA 16,35,55,107,110,110,255,16,28,30,36,56,62,64,106,110,110,255
35 DATA 16,33,56,62,67,102,255,16,32,54,57,60,61,66,74,76,101,255
36 DATA 17,32,54,56,61,61,63,63,65,74,76,99,255,17,31,54,55,58,58,66,74,76
37 DATA 95,97,97,102,102,255,18,30,55,59,68,96,98,101,255,18,30,54,96,99,99
38 DATA 255,19,25,28,29,53,96,255,20,24,29,29,52
39 DATA 67,69,96,255,21,24,51,68,70,75,78,96,255,22,27,51,68,70,77,79,95,255
40 DATA 23,27,51,69,71,77,80,85,87,92,255,26,27,29,31,51,69,71,75,80,83,88,91
41 DATA 96,96,255,28,32,35,37,51,69,80,83,88,91,255,32,38,52,73,81,83,88,90
42 DATA 255,31,39,53,73,82,82,89,90,97,97,255,30,42,59,72,89,90,255
43 DATA 30,44,59,71,93,95,255,30,45,60,70,93,95,255
44 DATA 30,44,60,69,103,104,255,30,44,61,69,104,105,255
45 DATA 31,44,61,69,102,103,255,32,43,60,70,72,72,98,100,102,104,255
46 DATA 33,43,60,69,71,72,97,105,255,33,42,60,69,71,72,95,105,255
47 RESTORE31
48 BEEP30,75:CLS:PRINT"COORDONNEES AUTO"
49 PRINT"Localisez ‰ l'aide":PRINT"du curseur puis":PRINT"appuyez RETURN";:GOSUB454
50 FORI=1TO500:NEXTI
51 CLS:L=0
52 READCD%
53 READCF%
54 LINE(CD%,L)-(CF%,L)
55 READRL%:IFRL%=255THENL=L+1:GOTO57
56 CD%=RL%:GOTO53
57 IFL<32THEN52
58 REM
59 XP=58:YP=6
60 PT=POINT(XP,YP)
61 IFPOINT(XP,YP)=0THENPSET(XP,YP)ELSEPRESET(XP,YP):BEEP10,1
62 Z$=INKEY$:IFZ$=""THENZ=0ELSEZ=ASC(Z$)
63 IFZ=13THENGOSUB71:GOTO73
64 IFZ>27ANDZ<32THENGOSUB71:GOTO66
65 IFZ=0THENFORI=1TO40:NEXTI:GOTO61
66 XP=XP-(Z=28)+(Z=29)
67 YP=YP+(Z=30)-(Z=31)
68 IFXP<11THENXP=118ELSEIFXP>118THENXP=11
69 IFYP<0THENYP=0ELSEIFYP>31THENYP=31
70 GOTO60
71 IFPT=0THENPRESET(XP,YP)ELSEPSET(XP,YP)
72 RETURN
73 LOCATE0,3:LG=-(XP-56)*2.6:LA=-(YP-23)*2.8
74 FU=-INT((LG+7.5)/15)
75 PRINT"Lg";USING"££££";LG;:PRINT"  Lt";USING"£££";LA;
76 PRINT" F";USING"£££";FU;:PRINT"h";
77 FORI=1TO500:NEXTI
78 GOTO452
79 REM
80 DEFFNDG(X)=SGN(X)*(INT(ABS(X))+(ABS(X)-INT(ABS(X)))/.6)
81 IFDP=99THENFU=0:LG=1:LA=9:GOTO111
82 PRINT"Coordonnes du dept"
83 LH$="0D>=HHMBC09à:E090,97QD%70HC00 A000?)00FF00A?*770>00AD0ID%"
84 LH$=LH$+"I<=80;<00:NMCHB0GH90:80:80JC+00I>L89998"
85 A=(ASC(MID$(LH$,DP+1,1))-48)/100:LG=-15*FNDG(A)
86 LA$=    ".1.,,+,1*0+,+1,-./-*/0.-/,100+++,+0./-.+/--//,,,/100000/"
87 LA$=LA$+"1.2102-++*00-/.0--0001.1+,++..-0//11111"
88 M=NJ+HL/24:LA=ASC(MID$(LA$,DP,1))
89 IFM<-3579THENE=A:GOTO101
90 IFM<3720THENE=.15:GOTO101
91 IFM>14300.9THENE=1
92 IFM<=14300.9ORM>15281.1THEN96
93 INPUT"Zone occupe (O/N)";Z$
94 ZO$=Z$:IFZ$="O"THENE=E+1:GOTO101
95 IFZ$<>"N"THENBEEP5,10:GOTO93
96 IFM>16330.1ANDM<27481.1THEN101
97 RESTORE102:FORI%=0TO40:READET:X=INT(ET)/10:Y=(ET-X*10)*1000
98 IFM>XANDM<X+YTHENE=E+1:I%=35:GOTO100
99 IFX+Y>MTHENI%=40
100 NEXTI%
101 FU=E
102 DATA 56449,1090,59279.1970,62779.2110,66349.2180,69849.2540
103 DATA 73789.2250,77549.1960,81819.1330,84899.1890,88609.1820
104 DATA 92389.1680,95959.1750,99669.1750,103379.1680,106949.1750
105 DATA 110659.1680,114159.1820,117729.1960,121509.1820,125079.1890
106 DATA 128929.1650,132429.1820,139849.2170,14349.1540,150430.2381
107 DATA 154281.1880,157990.1879,161630.1670,274810.1820,278520.1750
108 DATA 278520.1750,282160.1820,285810.1820,289470.1820,293120.1820
109 DATA 296770.1820,300420.1820,300480.1820,307730.1820,311380.1820
110 DATA 315030.1820
111 GOSUB75:RETURN
112 REM
113 INIT£1,"A.PARM":INPUT£1,A%,B%,C%
114 CLS:BEEP40,40:IFA%=0THEN119ELSEPRINT"Entre manuelle ?    frappez 'O'"
115 FORI=1TO500:IFINKEY$="O"THEN118
116 IFINKEY$="L"THENGOSUB435
117 NEXTI:CLS:GOTO144
118 REM
119 A%=A%+1:CLS:PRINT"Saisie THEME";A%
120 INPUT"NOM";N$:INPUT"Prnom";PR$:DP=0:ZO$=" ":Y=36525
121 INPUT"Sexe";SX$:IFSX$<>"M"ANDSX$<>"F"THENGOSUB149:GOTO121
122 INPUT"Jour";J:IFJ<1ORJ>31THENGOSUB149:GOTO122
123 D$=MID$(STR$(J),2,2)
124 INPUT"Mois";M:IFM<1ORM>12THENGOSUB149:GOTO124ELSED$=D$+STR$(M)
125 INPUT"Anne";A:IF A<1600ORA>2200THENGOSUB149:GOTO125:ELSED$=D$+STR$(A)
126 IFM>3THEN127ELSEA=A-1:M=M+12
127 T=INT(A*Y/100)+INT(30.6001*(M+1))+J-694023.5-INT(A/100)+INT(INT(A/100)/4)
128 T=T/Y:NJ=T*Y-364.5:NJ=INT(NJ*100)/100
129 INPUT"Heure lgale";HL:IFFIX(HL)>24THENGOSUB149:GOTO129
130 INPUT"Dpartement (0 si tranger)";DP:IFDP<0ORDP>99THENGOSUB149:GOTO130ELSEIFDP>95ANDDP<99THENGOSUB149:GOTO130
131 IFDP>0THENGOSUB79:GOTO139
132 INPUT" Coordonnes  AUTOMATIQUES (O/N)";Z$
133 IFZ$="O"THENGOSUB31:GOTO139
134 INPUT"Fuseau (Ngatif ‰ l'ouest)";FU
135 IFABS(FU)>=12THENGOSUB149:GOTO134
136 INPUT"Longitude (Ngative ‰ l'est)";LG
137 IF ABS(LG)>=180THENGOSUB149:GOTO136
138 INPUT"Latitude (Ngative au sud)";LA:IFFIX(LA)>=90THENGOSUB149:GOTO138
139 REM
140 FORI%=10TO40:BEEPI%,1:NEXTI%
141 TH$="F-"+MID$(STR$(A%),2,2):INIT£2,TH$,90:F$=CHR$(127)+STR$(A%)
142 GOSUB151:PRINT£2,DD$,NJ
143 PRINT£1,A%,B%,C%:GOTO112
144 REM
145 INIT£1,"A.PARM":INPUT£1,A%,B%,C%:B%=B%+1:TH$="F-"+MID$(STR$(B%),2,2)
146 INIT£2,TH$:INPUT£2,F$,N$,PR$,SX$,D$,HL,DP,FU,LG,LA,ZO$,NJ
147 CLS:PRINT"Traitement";B%:PRINTN$;PR$
148 RETURN
149 REM
150 FORI=1TO11:BEEP30,1:NEXTI:RETURN
151 REM
152 DEFFNZ$(X,X$)=LEFT$(X$,X)+STRING$((LEN(X$)-X)*(LEN(X$)<X)," ")+","
153 DEFFNY$(L,Z)=FNZ$(L,STR$(Z))
154 DD$=FNZ$(4,F$)+FNZ$(10,N$)+FNZ$(10,PR$)+FNZ$(1,SX$)+FNZ$(10,D$)+FNY$(6,HL)
155 DD$=DD$+FNY$(3,DP)+FNY$(6,FU)+FNY$(7,LG)+FNY$(6,LA)+ZO$:RETURN
156 REM
157 DEFFNF(D)=D-360*INT(D/360):DEFFNH(H)=H-24*INT(H/24)
158 DEFFNDG(X)=SGN(X)*(INT(ABS(X))+(ABS(X)-INT(ABS(X)))/.6)
159 HL=FNDG(HL):FU=FNDG(FU):LG=FNDG(LG):LA=FNDG(LA):LH=LG/15
160 TU=HL-FU:LC=TU-LG/15:LC=FNH(LC)
161 NJ=NJ+FNH(TU)/24:T=(NJ+364.5)/36525
162 TG=98.965+.985647342*NJ:TG=FNH(TG/15):TL=FNH(TG+LC)
163 A=15*TL/Z:E=.40932-T*.000227
164 DEFFNTG(N,D)=ATN(N/D)-2*PI*(N<0ANDD>0)-PI*(D<0):DIMC!(11)
165 G=SIN(A):D=COS(A)*COS(E):C!(9)=FNTG(G,D)
166 F=LA/Z:L=F:R=A:GOSUB167:C!(0)=FNTG(G,D):GOTO168
167 G=COS(R):D=-(SIN(E)*TAN(L)+COS(E)*SIN(R)):RETURN
168 L=ATN(TAN(F)/3):R=A-PI/3:GOSUB167:C!(10)=FNTG(G,D)
169 L=ATN(2*(TAN(F))/3):R=A+PI/6:GOSUB167:C!(1)=FNTG(G,D)
170 R=A-PI/6:GOSUB167:C!(11)=FNTG(G,D)
171 L=ATN(TAN(F)/3):R=A+PI/3:GOSUB167:C!(2)=FNTG(G,D)
172 FORJ=0TO2:C!(J)=FNF(C!(J)*Z):C!(J+6)=FNF(C!(J)+180):NEXTJ
173 FORJ=9TO11:C!(J)=FNF(C!(J)*Z):C!(J-6)=FNF(C!(J)+180):NEXTJ
174 REM
175 MA=0:MI=360:FORI=0TO11:IFC!(I)>=MATHENMA=C!(I):Q=I+1
176 IFC!(I)<=MITHENMI=C!(I)
177 NEXTI
178 DEFFNA(X)=INT(X*100)/100:HL=FNA(HL):NJ=FNA(NJ):LC=FNA(LC):TL=FNA(TL)
179 FU=FNA(FU):LG=FNA(LG):LA=FNA(LA)
180 RETURN
181 REM
182 N=M:FORJ=1TO10:N=M+E*SIN(N):NEXTJ
183 R=A-A*E*COS(N)
184 L=W+2*ATN(SQR((1+E)/(1-E))*TAN(N/2))
185 PRINTP$;:R!(P)=R:RETURN
186 W=L-D:L=ATN(COS(I)*SIN(W)/COS(W))+D:IFCOS(W)<0THENL=L+PI
187 E=SIN(W)*SIN(I):E=ATN(E/SQR(-E*E+1))
188 H!(P)=FNF(L*Z)
189 A=R*SIN(E):I=R*COS(E)*COS(L)+X:J=R*COS(E)*SIN(L)+Y
190 IFABS(FNF(L*Z)-L0)<PHTHENS$="R"ELSES$=" "
191 SS$=SS$+S$
192 L=ATN(J/I):IFI<0THENL=L+PI
193 G!(P)=FNF(L*Z)
194 J=SQR(J*J+I*I+A*A):E=A/J:E=ATN(E/SQR(-E*E+1)):GOSUB202
195 L!(P)=E*Z
196 GOSUB198
197 GOSUB206:G=H:GOSUB206:RETURN
198 IFG!(P)>=MAORG!(P)<MITHENMM=Q:GOTO201
199 MM=12:FORJ=0TO10:IFG!(P)>=C!(J)ANDG!(P)<C!(J+1)THENMM=J+1:J=10
200 NEXTJ
201 MM$=MM$+CHR$(MM+65):RETURN
202 G=(ATN((B*SIN(L)-TAN(E)*C)/COS(L)))*Z:IFCOS(L)<0THENG=G+180
203 IFG<0THENG=G+360
204 H=SIN(E)*B+COS(E)*C*SIN(L):H=(ATN(H/SQR(-H*H+1)))*Z
205 RETURN
206 G=G*100:J=G-INT(G):IFJ>.49999THENG=G+1
207 PRINTUSINGU$;INT(G)/100;:RETURN
208 REM
209 P$=" Soleil":P=0
210 A=1:E=.016751-.000042*T:M=6.256584+T*628.301946:W=T*.030005-1.374956
211 J=.40932-T*.000227
212 B=COS(J):C=SIN(J):GOSUB182:X=R*COS(L):Y=R*SIN(L)
213 H!(P)=FNF(L*Z+180):G!(P)=FNF(L*Z):GOSUB198
214 L0=L*Z+180:E=0:GOSUB202
215 GOSUB206
216 G=H:GOSUB206:PRINT
217 P$="   Lune":P=1:PRINTP$;
218 L=278.965+.985647342*NJ:W=281.235+.0000469*NJ:M=L-W
219 L1=33.231+13.17639653*NJ:W1=239.882-.052953922*NJ:M1=18.294+13.06499245*NJ
220 H!(P)=FNF(W1)
221 D=L1-L:F=L1-W1
222 L1=L1/Z:M=M/Z:M1=M1/Z:D=D/Z:F=F/Z
223 L=L1+1.097593933E-1*SIN(M1)+3.72802E-3*SIN(2*M1)
224 L=L+1.14895E-2*SIN(2*D)-3.23931092E-3*SIN(M)
225 L=L+2.223549467E-2*SIN(2*D-M1)-1.9949E-3*SIN(2*F)
226 L=L+1.026253E-3*SIN(2*D-2*M1)+9.98328E-4*SIN(2*D-M1-M)
227 L=L+9.3026049E-4*SIN(2*D+M1)+8.0110612E-4*SIN(2*D-M)
228 L=L+7.155899E-4*SIN(M1-M)-5.3232542E-4*SIN(M1+M)-6.07374579E-4*SIN(D)
229 L=L-.000532*SIN(M+M1)+.000267*SIN(D+D-F-F)-.000219*SIN(F+F+M1)
230 E=8.9500484E-2*SIN(F)+4.89739388E-3*SIN(M1+F)
231 E=E+4.84677933E-3*SIN(M1-F)+3.02291026E-3*SIN(2*D-F)
232 E=E+9.66912405E-4*SIN(2*D-M1+F)+8.06342114E-4*SIN(2*D-M1-F)
233 E=E+5.68977336E-4*SIN(2*D+F)
234 GOSUB202
235 G!(P)=FNF(L*Z):L!(P)=E*Z:GOSUB198
236 GOSUB206
237 G=H:GOSUB206:PRINT
238 P$="Mercure":P=2
239 A=.387099:E=.205614+T*.000002:I=.122223+T*.000032:M=1.785112+T*2608.787533
240 W=1.3247+T*.027148:D=.822852+T*.020686
241 GOSUB182:PH=35.6:GOSUB186:PRINT
242 P$="  Venus":P=3
243 A=.723332:E=.006821-T*.000048:I=.05923+T*.000018:M=3.710626+T*1021.328349
244 W=2.271787+T*.024575:D=1.322604+T*.015705
245 GOSUB182:PH=13:GOSUB186:PRINT
246 P$="   Mars":P=4
247 A=1.523688:E=.093313+T*.000092:I=.032294-T*.000012
248 M=5.576661+T*334.053484:W=.032127*T-.449977:D=.851484+T*.013456
249 GOSUB182:PH=16.8:GOSUB186:PRINT
250 K=2.349761+T*.711349
251 P$="Jupiter":P=5
252 A=5.20256-.000026*COS(K):E=.048335+T*.000164+.000361*SIN(K)+.000129*COS(K)
253 I=.022842-T*.000099:M=3.932721+T*52.965368+.007442*COS(K)+.003176*SIN(K)
254 W=.222022+T*.028099-.007386*COS(K)+.002507*SIN(K):D=1.735615+T*.017637
255 GOSUB182:PH=54.43:GOSUB186:PRINT
256 P$="Saturne":P=6
257 A=9.554747+.000057*SIN(K)+.000293*COS(K)
258 E=.055892-T*.000346-.000793*SIN(K)+.001338*COS(K):I=.043503-T*.000068
259 M=3.062463+T*21.320095-.0383*SIN(K)-.014478*COS(K)
260 W=1.589963+T*.034181+.024079*SIN(K)+.014295*COS(K):D=1.968564+T*.01524
261 GOSUB182:GOSUB186:PH=65.53:PRINT
262 P$=" Uranus":K=4.958028+T*.148533:A=19.21814-.003824*COS(K):P=7
263 E=.046344-T*.000027-.000335*SIN(K)+.0021*COS(K):I=.013482+T*.000011
264 M=1.26796+T*7.476626-.030225*SIN(K)-.005875*COS(K)
265 W=2.99409+T*.025908+.045305*SIN(K)+.007306*COS(K):D=1.282418+T*.008703
266 GOSUB182:PH=73.92:GOSUB186:PRINT
267 P$="Neptune":P=8
268 A=30.10957+.01058*COS(K)
269 E=.008997+T*.000006+.00044*SIN(K)+.000426*COS(K):I=.031054-T*.000167
270 M=.658524+T*3.81287-.056901*SIN(K)+.047519*COS(K)
271 W=.815546+T*.024863+.046558*SIN(K)-.048498*COS(K):D=2.280821+T*.01918
272 GOSUB182:PH=77.63:GOSUB186:PRINT
273 P$=" Pluton":P=9
274 A=39.43871:E=.250236:I=.299681:M=4.000635+T*2.536813:W=3.909712:D=1.915324
275 GOSUB182:PH=79.41:GOSUB186:PRINT
276 SS$="   "+SS$:RETURN
277 PRINT"RAZ tableau"
278 DEFFNRG(L,C)=L*12+C+AD:DEFFNP(L,C)=PEEK(FNRG(L,C)):DIM B(11)
279 DEFFNAS(X)=ATN(X/SQR(1-X*X)):PI=3.14
280 FORI%=ADTOAD+539:POKEI%,0:NEXTI%
281 FORI%=0TO9:B(I%+2)=G!(I%):NEXTI%:B(0)=C!(9):B(1)=C!(0)
282 FORI%=0TO11:POKEFNRG(0,I%),INT(B(I%))/30:NEXTI%
283 FORI%=0TO9:POKEFNRG(1,I%+2),ASC(MID$(MM$,I%+1,1))-66:NEXTI%
284 S$="300210400103456000060050020020010043220010000066000014060060"
285 S$=S$+"400120300204365000050000010010020034110020000055000023050050"
286 FORI=2TO11:POKEFNRG(2,I),VAL(MID$(S$,10*FNP(0,I)+I-1,1))
287 IFMID$(SS$,I,1)="R"THENPOKEFNRG(30,I),1
288 NEXTI
289 FORC=0TO11:POKEFNRG(3,C),VAL(MID$("654324567887",FNP(0,C)+1,1))
290 POKEFNRG(20,C),INT(C!(C)/30)
291 POKEFNRG(21,C),VAL(MID$("654324567887",FNP(20,C)+1,1)):NEXTC
292 E=COS(10/Z):F=COS(55/Z):H=COS(65/Z):PRINT"Calcul ASPECTS"
293 F!=COS(43/Z):H!=COS(45/Z):FORC=0TO11:FORL=4TO13
294 D=(B(C)-B(L-2))*PI/180:M=COS(D):A=0
295 IFM>=ETHENA=1:GOTO300
296 IFABS(M)>=EANDM<0THENA=2:GOTO300
297 IFM>=HANDM<=FTHENA=6:GOTO300
298 IFM>=-FANDM<=-HTHENA=3:GOTO300
299 IFABS(SIN(D))>=ETHENA=4ELSEIFM>=H!ANDM<=F!THENA=8
300 IFA=0THEN308
301 D=D*180/PI:G=360/A:GOSUB311
302 I=-I*(I<G/2)-(G-I)*(I>=G/2)
303 IFI>11-ATHENA=0:GOTO308
304 D=FNP(0,C):G=4:GOSUB311
305 X=I:D=FNP(0,L-2):GOSUB311:Y=I
306 IFA=3ANDX<>YTHENA=0
307 IFA=4ANDX=YTHENA=0
308 POKEFNRG(C+4,L-2),A
309 IFC+2=LTHENPOKEFNRG(C+4,L-2),9
310 NEXTL:NEXTC:GOTO312
311 I=INT(.1+G*(D/G-INT(D/G))):RETURN
312 RETURN
313 PRINT"Impres. rsultats":U$="££££.££"
314 LPRINT°3,0§"THEME No ";B%:LPRINT°2,3§"    NOM:   ";N$;"    ";PR$
315 LPRINT"    Ne";:IFSX$="F"THEN LPRINT"e";
316 V$="LUNDI   MARDI   MERCREDIJEUDI   VENDREDISAMEDI  DIMANCHE"
317 LPRINT" LE ";MID$(V$,(INT((7+1E-4)*((NJ/7)-INT(NJ/7))))*8+1,8);"  ";D$:IFHL=0THEN331
318 LPRINT "Signe ";:I%=INT(G!(0))/30:GOSUB328:LPRINT"  ";
319 LPRINT"Ascendant  ";:I%=INT(C!(0))/30:GOSUB328:LPRINT:GOTO331
320 REM
321 VR$="I   II  III IV  V   VI  VII VIIIIX  X   XI  XII "
322 LPRINTMID$(VR$,(I%*4)+1,4);:RETURN
323 REM
324 VR$="Mi-CIELAscend.Soleil Lune   MercureVenus  Mars   Jupiter"
325 VR$=VR$+"SaturneUranus NeptunePluton "
326 LPRINTMID$(VR$,(I%*7)+1,7);:RETURN
327 REM
328 VR$="Belier    Taureau   Gemeaux   Cancer    Lion      Vierge    "
329 VR$=VR$+"Balance   Scorpion  SagittaireCapricorneVerseau   Poisson   "
330 LPRINTMID$(VR$,I%*10+1,10);:RETURN
331 DEFFNDM(X)=SGN(X)*(INT(ABS(X))+(ABS(X)-INT(ABS(X)))*.6)
332 LPRINT°1,0§"DATE";TAB(22);D$
333 LPRINT"HEURE LEGALE";:IFHL=0THENLPRINTTAB(22);"Inconnue (0h PARIS)"
334 IFHL<>0THENLPRINTTAB(22);FNDM(HL);"     (";FNDM(HL-FU);"GMT)"
335 IFDP<>0THENLPRINT"DEPARTEMENT";TAB(22);DP;
336 IFDP<>0ANDZO$="O"THENLPRINT" Zone occupee";
337 LPRINT:LPRINT"FUSEAU";TAB(22);FNDM(FU)
338 LPRINT"LONGITUDE";TAB(22);FNDM(LG);" deg."
339 LPRINT"LATITUDE ";TAB(21);FNDM(LA);" deg."
340 LPRINT"HEURE LOCALE";TAB(20);USING U$;FNDM(LC)
341 LPRINT"Temps sideral local";TAB(20);USINGU$;FNDM(TL)
342 LPRINT"Nb jours";TAB(18);NJ
343 IFHL=0THENLPRINT"le theme ne peut etre domifie":GOTO348
344 LPRINTCHR$(18):LPRINT"M0,107":LPRINT"A"
345 LPRINTTAB(50);"Cuspide des 12 maisons":LPRINT
346 FORI=0TO5:LPRINTTAB(56);USINGU$;FNDM(C!(I));
347 LPRINTTAB(71);USINGU$;FNDM(C!(I+6)):NEXTI:LPRINT
348 REM
349 LPRINTCHR$(18):LPRINT"I":LPRINT"D470,0,470,-158,0,-158,0,0,0,-26,470,-26"
350 LPRINT"M52,0":LPRINT"D52,-158,101,-158,101,0,202,0,202,-158,252,-158"
351 LPRINT"D252,0,285,0,285,-158,331,-158,331,0,376,0,376,-158,426,-158,426,0"
352 LPRINT"M0,-08":LPRINT"A"
353 LPRINTTAB(10);"Long g";TAB(22);"Signe";TAB(35);"Maison";TAB(43);"Sens";
354 LPRINTTAB(49);"Noeud";TAB(56);"Lat g";TAB(64);"Long h";TAB(72);"Rayon"
355 LPRINT
356 DEFFNDS(X)=FNDM(X-30*INT(X/30))
357 FORI=0TO9
358 I%=I+2:LPRINT" ";:GOSUB323
359 LPRINTTAB(09);USINGU$;FNDM(G!(I));FNDS(G!(I));
360 LPRINTTAB(24);:I%=INT(G!(I)/30):GOSUB327
361 IFHL<>0THENLPRINTTAB(37);:I%=FNP(1,I+2):GOSUB320
362 IFFNP(30,I+2)=1THENLPRINTTAB(44);"R";
363 IFI=1THENLPRINTTAB(47);USINGU$;FNDM(H!(I));
364 LPRINTTAB(55);USING"£££.££";FNDM(L!(I));
365 IFI<>1THENLPRINTTAB(63);USINGU$;FNDM(H!(I));
366 LPRINTTAB(71);USING"£££.££";R!(I)
367 NEXTI:LPRINT:LPRINT:LPRINT:RETURN
368 V1$=V$:FORV%=1TOI:V1%=INSTR(V1$,V3$):V2%=LEN(V1$)
369 IFV1%=0THENV1%=V2%+1:V2%=V1%
370 V2$=LEFT$(V1$,V1%-1):IFV1%<=V2%THENV1$=RIGHT$(V1$,V2%-V1%)
371 NEXTV%:RETURN
372 REM
373 DEFFNM$(X,Y)="M"+STR$(X)+","+STR$(Y)
374 DEFFND$(X,Y)="D"+STR$(X)+","+STR$(Y)
375 DEFFNAC(X)=ATN(SQR(1-X*X)/X)/Z
376 DEFFNRG(L,C)=L*12+C+AD:DEFFNP(L,C)=PEEK(FNRG(L,C))
377 PI=3.14:Z=PI/180:RETURN
378 LPRINTCHR$(18):LPRINT"S2,C0":LPRINT"PCARTE   DU   CIEL":LPRINT"S1"
379 GOSUB372
380 K=2:LPRINTFNM$(225,-230):LPRINT"I"
381 N1=25:S1=3*K:A=0:B=0:GOSUB420
382 GOSUB385
383 GOSUB393
384 LPRINTFNM$(-225,-220):LPRINT"A":RETURN
385 C=-C!(0)+180:D=70*K:FORJ=1 TO2:GOSUB419:LPRINTFNM$(A,B)
386 FORI=1TO36:C=C+10:GOSUB419:LPRINTFND$(A,B)
387 IFJ=1THENLPRINTFND$(.97*A,.97*B):LPRINTFND$(A,B):GOTO389
388 IFI-3*INT(I/3)=0THENLPRINTFND$(3/2*A,3/2*B):LPRINTFND$(A,B)
389 NEXTI:D=140/3*K:NEXTJ
390 C=-C!(0)+195:D=35*K+D/2
391 LPRINT"C1"
392 S1=3*K:A1=0:FORN1=1TO12:GOSUB419:GOSUB420:C=C+30:NEXTN1:RETURN
393 IFNJ-INT(NJ)=0THEN401
394 LPRINT"S1,C2":D=90*K:LPRINTFNM$(D,0):LPRINTFND$(.8*D,0)
395 LPRINTFNM$(-.8*D,0):LPRINTFND$(-D,0):LPRINTFNM$(-D,5):LPRINT"PAS"
396 C=C!(0)-C!(9):GOSUB419:LPRINTFNM$(A,-B):LPRINTFND$(.8*A,-.8*B)
397 LPRINTFNM$(-.8*A,.8*B):LPRINTFND$(-A,B)
398 LPRINTFNM$(-A-15,B):LPRINT"PM.C"
399 D=75*K:N1=23:FORI%=10TO11:C=C!(I%)-C!(0):GOSUB417
400 C=C!(I%-9)-C!(0):GOSUB417:NEXTI%
401 FORH=0TO9:S1=0:IFH=9THEN414
402 FORI=H+1TO9:C=G!(H)-C!(0)+180:D=46*K:GOSUB419:LPRINTFNM$(A,B)
403 T=FNP(H+6,I+2):IFT=0ORT=8THEN413
404 ONTGOTO405,406,407,408,409,410
405 S1=S1+15*K:GOTO413
406 J=3:M=1:GOTO411
407 J=1:M=0:GOTO411
408 J=3:M=0:GOTO411
409 GOTO413
410 J=1:M=0
411 C=G!(I)-C!(0)+180:GOSUB419:LPRINT"C"+STR$(J)+",L"+STR$(M)
412 LPRINTFND$(A,B)
413 NEXTI
414 C=G!(H)-C!(0)+180:D=70*K:GOSUB419:LPRINT"L0,C3"
415 LPRINTFNM$(A,B):LPRINTFND$(1.1*A,1.1*B)
416 D=85*K+S1:GOSUB419:S1=2.5*K:N1=H+13:GOSUB420:NEXTH:RETURN
417 GOSUB419:LPRINTFNM$(A,B):D=80*K:GOSUB419:LPRINTFND$(A,B)
418 C=C+180:GOSUB419:LPRINTFNM$(A,B):D=75*K:GOSUB419:LPRINTFND$(A,B):RETURN
419 A=D*COS(C*Z):B=D*SIN(C*Z):RETURN
420 IFN1>12THEN425
421 V$="217?àHJD<:à?EMN,823;IONF 08FL,1M 5Q 8< FJ,FàHNF82 <B:4<JP,"
422 V$=V$+"29:327EMOBDKQ,28;9?BàFIQ GMPJ,3:9?GHO 4P,1428;9?BN GNO,"
423 V$=V$+"5M FMN :B,1<àFGND,39AGO 4:BHP,09;6 LGIR :H"
424 V3$=",":I=N1:GOSUB368:GOTO429
425 V$=":BHà: 4<JPNF824,?GIC<Bà8?,08FL BD <J 823;IONF8,<J BD 823;IONF8,"
426 V$=V$+"8FL ELM 823;IONF8,17>FG45J BD,05:AICDKQ 29,?B<DJB 8: FH 9G,"
427 V$=V$+"?C 19GM ;I,;IONF8=D,BF8B,4<JPNF824 ?C 3O,?E7?B= BK 39GO"
428 I=N1-12:V3$=",":GOSUB368
429 LPRINTFNM$(A,B):LPRINT"I":Z$=" "+V2$
430 FORV1=1TOLEN(Z$)
431 Z1=ASC(MID$(Z$,V1,1))-48:IFZ1=-16THENE1=9:V1=V1+1:GOTO431
432 X1=INT(Z1/7):Y1=(7*X1+3-Z1)*S1:X1=(X1-2)*S1
433 IFE1=9THENLPRINTFNM$(X1,Y1)ELSELPRINTFND$(X1,Y1)
434 E1=0:NEXTV1:A1=0:LPRINTFNM$(-A,-B):LPRINT"I":RETURN
435 LPRINT°1,0§"LISTE DES FICHIERS"
436 INIT£1,"A.PARM":INPUT£1,A%,B%,C%:LPRINTA%;B%;C%:IFA%=0THEN439
437 FORI=1TOA%:TH$="F-"+MID$(STR$(I),2,2):INIT£2,TH$:LINEINPUT£2,A$
438 LPRINTA$:PRINTLEFT$(A$,20);:NEXTI:PRINTA%;B%;C%
439 RETURN
440 REM
441 IFERR=24ANDERL=6THENGOSUB450:RESUME
442 IFERR=24THENCLS:PRINT"Fichier puis":GOSUB444:END
443 PRINT"erreur";ERR;:FOROO=1TO5:GOSUB150:NEXTOO:RESUME1
444 REM
445 INIT£1,"A.PARM",300:INPUT£1,A%,B%,C%:IFA%=0THEN451
446 PRINT"J'efface tous les";A%;"thmes O/N?";
447 Z$=INKEY$:IFZ$=""THEN447
448 IFZ$="O"THENGOSUB435:PRINTZ$:ELSEPRINT"N";:GOTO451
449 FORI=1TOA%:TH$="F-"+MID$(STR$(I),2,2):DELETETH$,"D":NEXTI
450 INIT£1,"A.PARM",20:PRINT£1,0,0,0
451 RETURN
452 ONERRORGOTO453:SCREEN2,2,2:COLOR2,3,1
453 RETURN
454 ONERRORGOTO455:SCREEN1,1,1
455 RETURN