Suite à la gazette n°3: Rien que du Sierpinski sur PSION 3a

[ledudu]

Intéressé par le programme récursif de zPALM mais dépourvu de hpPrime, j'ai adapté son algorithme sur mon psion Series 3A.

Code : Tout sélectionner

PROC Main:
   LOCAL Lv1%
   LV1%=3
   Srpinski:(240,0,160,159,320,159,Lv1%)
   GET
ENDP

PROC Srpinski:(P11%,P12%,P21%,P22%,P31%,P32%,Lv1%)
    IF LV1%>0
         Srpinski:(P11%,P12%,(P11%+P21%)/2,(P12%+P22%)/2,(P11%+P31%)/2,(P12%+P32%)/2,LV1%-1)
         Srpinski:((P11%+P21%)/2,(P12%+P22%)/2,P21%,P22%,(P21%+P31%)/2,(P22%+P32%)/2,LV1%-1)
         Srpinski:((P11%+P31%)/2,(P12%+P32%)/2,(P21%+P31%)/2,(P22%+P32%)/2,P31%,P32%,LV1%-1)
   ELSE
         POLY3:(P11%,P12%,P21%,P22%,P31%,P32%)
   ENDIF
ENDP

PROC POLY3:(P11%,P12%,P21%,P22%,P31%,P32%)
   LOCAL C%(9)
   C%(1)=P11%
   C%(2)=P12%
   C%(3)=3
   C%(4)=2*(P21%-P11%)
   C%(5)=P22%-P12%
   C%(6)=2*(P31%-P21%)
   C%(7)=P32%-P22%
   C%(8)=2*(P11%-P31%)
   C%(9)=P12%-P32%
  gPOLY C%()
  REM Remplissage récursif du triangle par triangles successifs décroissants
  IF ABS(P21%-P31%)>1 AND ABS(P22%-P12%)>1
      POLY3:(P11%,P12%+1,P21%+1,P22%-1,P31%-1,P32%-1)
  ENDIF
ENDP     

J'ai abandonné les trois vecteurs de la version d'origine parce que l'on ne peut pas passer de tableaux en paramètres.
Le triangle est tracé avec la fonction gPOLY plus rapide que de faire 3 gLINEBY.
La fonction gPOLY attend 3+2xN paramètres ou N est le nombre de sommets.
- les deux coordonnées initiales
- le nombre de sommets N (ici 3)
puis 3 fois:
- (2*dx) (2 fois la différence des abscisses des sommets successifs - pourquoi 2 fois ? I don't know)
- dy (différence des ordonnées des sommets successfs)

Il n'y a pas de fonction gFILL sur un triangle, je remplis avec des triangles plus petits.

Le résultat est très sympa (surtout le tracé, relativement rapide).




Merci zPALM.

[Marge]

Bravo, c'est une très bonne machine, et visiblement un bon programme.

Tu n'as pas encore essayé le "tricarré" de Sierpinski ?

[ledudu]

Tu n'as pas encore essayé le "tricarré" de Sierpinski ?

Je suis sur le carré, je m'attaquerai au tri-carré ensuite.

[gege]

Bonjour,
Sympa et pas si long que cela, on sent l'effort de mise au point.

N'y aurait-il pas un 'g' en trop au début de "gPOLY3:(P11%,P12%+1,..." ?
Le facteur 2 est-il lié à la résolution plus fine selon l'axe des abscisses (est-ce que le tracé est juste compressé sans ce 2) ?
On dirait aussi que le format de gPOLY est : 3 valeurs, puis 2xN valeurs avec N=nombre de sommets, non ?

Ca donne envie de ressortir un Psion !
Merci
G.E.

[zpalm]

Joli ! !

Entre ce programme et l'article de Tyann il va falloir que je ressorte mon Psion....

Juste une petite remarque : dans Poly3 ce ne serais pas plutôt C%(2)=P12% au lieu de C%(2)=P21% ?

[ledudu]

Tu as raison zPalm, je corrige.
J'ai retapé le programme sans faire de transfert, il y a peut-être d'autres coquilles.

[ledudu]

Fin d'un après-midi pluvieux :

[ledudu]

@gégé : corrigé, merci.
Sans le fois deux, le tracé est déplacé.

[bernouilli92]

Pas mal, merci.

Il reste une petite erreur dans le listing : le dernier paramètre dans l'appel des 3 procédures srpinski dans la procédure srpinski doit être LV1%-1

[ledudu]

@Bernouilli : corrigé, merci.

[zpalm]

Fin d'un après-midi pluvieux :

Superbe !!

J'ai essayé le triangle sur mon Psion Séries 3 (pas a), le programme marche bien mais je suis vite limité par la définition de l'écran qui est un quart de celle du 3a (240x80 vs.480x160).



Sur la HP Prime j’obtiens ceci pour un tri-carré de niveau 5:

[zpalm]

Une petite video sur la construction du tri-carré(5) sur HP Prime:

[ledudu]

Mon code pour le triangle, le carré et le tri-carré (récupéré par liaison série)

Code : Tout sélectionner

EM xxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM xxxxx PROC S_triangle xxxxxx
REM xxxxxxxxxxxxxxxxxxxxxxxxxxx
PROC Striang:(Lv1%)
       Srpinski:(240,0,160,159,320,159,Lv1%)
       GET
ENDP

REM xxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM xxxxx PROC S_carre xxxxxx
REM xxxxxxxxxxxxxxxxxxxxxxxxxxx
PROC Scarre:(Lv1%)
       SpinskiC:(0,0,480,0,480,159,0,159,Lv1%)
       GET
ENDP

REM xxxxxxxxxxxxxxxxxxxxxxxxxxxx
REM xxxxx PROC Stricarr xxxxxx
REM xxxxxxxxxxxxxxxxxxxxxxxxxxx
PROC Stricar:(Lv1%)
       SpinskTC:(0,0,480,0,480,159,0,159,Lv1%)
       GET
ENDP

REM lancement du triangle
PROC Srpinski:(P11%,P12%,P21%,P22%,P31%,P32%,Lv1%)
    IF Lv1%>0
       Srpinski:(P11%,P12%,(P11%+P21%)/2,(P12%+P22%)/2,(P11%+P31%)/2,(P12%+P32%)
/2,Lv1%-1)
       Srpinski:((P11%+P21%)/2,(P12%+P22%)/2,P21%,P22%,(P21%+P31%)/2,(P22%+P32%)
/2,Lv1%-1)
       Srpinski:((P11%+P31%)/2,(P12%+P32%)/2,(P31%+P21%)/2,(P32%+P22%)/2,P31%,P3
2%,Lv1%-1)
    ELSE
       POLY3:(P11%,P12%,P21%,P22%,P31%,P32%,0)
    ENDIF
ENDP

REM dessin d'un triangle plein
PROC POLY3:(P11%,P12%,P21%,P22%,P31%,P32%,N%)
   LOCAL C%(9)
   C%(1)=P11%
   C%(2)=P12%
   C%(3)=4
   C%(4)=2*(P21%-P11%)
   C%(5)=P22%-P12%
   C%(6)=2*(P31%-P21%)
   C%(7)=P32%-P22%
   C%(8)=2*(P11%-P31%)
   C%(9)=P12%-P32%

   gPOLY C%()
   IF (ABS(P21%-P31%)>1 AND ABS(P22%-P12%)>1) OR (ABS(P22%-P32%)>1 AND ABS(P21%-
P11%)>1)
      IF N%=0
         POLY3:(P11%,P12%+1,P21%+1,P22%-1,P31%-1,P32%-1,N%)
      ELSEIF N%=1
         POLY3:(P11%+1,P12%+1,P21%+1,P22%-2,P31%-2,P32%+1,N%)
      ELSEIF N%=2
         POLY3:(P11%+2,P12%+1,P21%-1,P22%-2,P31%-1,P32%+1,N%)
      ELSEIF N%=3
         POLY3:(P11%-1,P12%+2,P21%+2,P22%-1,P31%-1,P32%-1,N%)
      ELSE
         POLY3:(P11%+1,P12%+2,P21%+1,P22%-1,P31%-2,P32%-1,N%)
      ENDIF
   ENDIF
ENDP

REM Lancement du carré
PROC SpinskiC:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinskiC:(P11%,P12%,S%:(P11%,P21%),S%:(P12%,P22%),S%:(P11%,P31%),S%:(P12%
,P32%),S%:(P11%,P41%),S%:(P12%,P42%),Lv1%-1)
       SpinskiC:(S%:(P11%,P21%),S%:(P12%,P22%),S%:(P21%,P11%),S%:(P22%,P12%),S%:
(P21%,P41%),S%:(P22%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),Lv1%-1)
       SpinskiC:(S%:(P21%,P11%),S%:(P22%,P12%),P21%,P22%,S%:(P21%,P31%),S%:(P22%
,P32%),S%:(P21%,P41%),S%:(P22%,P42%),Lv1%-1)
       SpinskiC:(S%:(P21%,P41%),S%:(P22%,P42%),S%:(P21%,P31%),S%:(P22%,P32%),S%:
(P31%,P21%),S%:(P32%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),Lv1%-1)
       SpinskiC:(S%:(P31%,P11%),S%:(P32%,P12%),S%:(P31%,P21%),S%:(P32%,P22%),P31
%,P32%,S%:(P31%,P41%),S%:(P32%,P42%),Lv1%-1)
       SpinskiC:(S%:(P41%,P21%),S%:(P42%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),S%:
(P31%,P41%),S%:(P32%,P42%),S%:(P41%,P31%),S%:(P42%,P32%),Lv1%-1)
       SpinskiC:(S%:(P41%,P11%),S%:(P42%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),S%:
(P41%,P31%),S%:(P42%,P32%),P41%,P42%,Lv1%-1)
       SpinskiC:(S%:(P11%,P41%),S%:(P12%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),S%:
(P41%,P21%),S%:(P42%,P22%),S%:(P41%,P11%),S%:(P42%,P12%),Lv1%-1)
    ELSE
       POLY4:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%)
    ENDIF
ENDP
PROC S%:(X%,Y%)
   RETURN (2*X%+Y%)/3
ENDP

REM dessin d'un carré
PROC POLY4:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%)
   LOCAL C%(11)
   C%(1)=P11%
   C%(2)=P12%
   C%(3)=4
   C%(4)=2*(P21%-P11%)
   C%(5)=P22%-P12%
   C%(6)=2*(P31%-P21%)
   C%(7)=P32%-P22%
   C%(8)=2*(P41%-P31%)
   C%(9)=P42%-P32%
   C%(10)=2*(P11%-P41%)
   C%(11)=P12%-P42%
   gPOLY C%()
   IF ABS(P11%-P31%)>1 AND ABS(P12%-P32%)>1
      POLY4:(P11%+1,P12%+1,P21%-1,P22%+1,P31%-1,P32%-1,P41%+1,P42%-1)
   ENDIF
ENDP

REM lancement du carré triangle
PROC SpinskTC:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinskTC:(P11%,P12%,S%:(P11%,P21%),S%:(P12%,P22%),S%:(P11%,P31%),S%:(P12%
,P32%),S%:(P11%,P41%),S%:(P12%,P42%),Lv1%-1)
       SpinsTC1:(S%:(P11%,P21%),S%:(P12%,P22%),S%:(P21%,P11%),S%:(P22%,P12%),S%:
(P21%,P41%),S%:(P22%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),Lv1%-1)
       SpinskTC:(S%:(P21%,P11%),S%:(P22%,P12%),P21%,P22%,S%:(P21%,P31%),S%:(P22%
,P32%),S%:(P21%,P41%),S%:(P22%,P42%),Lv1%-1)
       SpinsTC2:(S%:(P21%,P41%),S%:(P22%,P42%),S%:(P21%,P31%),S%:(P22%,P32%),S%:
(P31%,P21%),S%:(P32%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),Lv1%-1)
       SpinskTC:(S%:(P31%,P11%),S%:(P32%,P12%),S%:(P31%,P21%),S%:(P32%,P22%),P31
%,P32%,S%:(P31%,P41%),S%:(P32%,P42%),Lv1%-1)
       SpinsTC3:(S%:(P41%,P21%),S%:(P42%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),S%:
(P31%,P41%),S%:(P32%,P42%),S%:(P41%,P31%),S%:(P42%,P32%),Lv1%-1)
       SpinskTC:(S%:(P41%,P11%),S%:(P42%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),S%:
(P41%,P31%),S%:(P42%,P32%),P41%,P42%,Lv1%-1)
       SpinsTC4:(S%:(P11%,P41%),S%:(P12%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),S%:
(P41%,P21%),S%:(P42%,P22%),S%:(P41%,P11%),S%:(P42%,P12%),Lv1%-1)
       SpinskTC:(S%:(P11%,P31%),S%:(P12%,P32%),S%:(P21%,P41%),S%:(P22%,P42%),S%:
(P31%,P11%),S%:(P32%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),Lv1%-1)
    ELSE
       POLY4:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%)
    ENDIF
ENDP

REM Carré avec triangle vide en bas à droite
PROC SpinsTC1:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinskTC:(P11%,P12%,S%:(P11%,P21%),S%:(P12%,P22%),S%:(P11%,P31%),S%:(P12%
,P32%),S%:(P11%,P41%),S%:(P12%,P42%),Lv1%-1)
       SpinsTC1:(S%:(P11%,P21%),S%:(P12%,P22%),S%:(P21%,P11%),S%:(P22%,P12%),S%:
(P21%,P41%),S%:(P22%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),Lv1%-1)
       SpinsTC1:(S%:(P21%,P11%),S%:(P22%,P12%),P21%,P22%,S%:(P21%,P31%),S%:(P22%
,P32%),S%:(P21%,P41%),S%:(P22%,P42%),Lv1%-1)
       SpinsTC1:(S%:(P41%,P11%),S%:(P42%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),S%:
(P41%,P31%),S%:(P42%,P32%),P41%,P42%,Lv1%-1)
       SpinsTC4:(S%:(P11%,P41%),S%:(P12%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),S%:
(P41%,P21%),S%:(P42%,P22%),S%:(P41%,P11%),S%:(P42%,P12%),Lv1%-1)
       SpinsTC1:(S%:(P11%,P31%),S%:(P12%,P32%),S%:(P21%,P41%),S%:(P22%,P42%),S%:
(P31%,P11%),S%:(P32%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),Lv1%-1)
    ELSE
       POLY3:(P11%,P12%,P41%,P42%,P21%,P22%,1)
    ENDIF
ENDP
REM Carré avec triangle vide en bas à gauche
PROC SpinsTC2:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinsTC2:(P11%,P12%,S%:(P11%,P21%),S%:(P12%,P22%),S%:(P11%,P31%),S%:(P12%
,P32%),S%:(P11%,P41%),S%:(P12%,P42%),Lv1%-1)
       SpinsTC1:(S%:(P11%,P21%),S%:(P12%,P22%),S%:(P21%,P11%),S%:(P22%,P12%),S%:
(P21%,P41%),S%:(P22%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),Lv1%-1)
       SpinskTC:(S%:(P21%,P11%),S%:(P22%,P12%),P21%,P22%,S%:(P21%,P31%),S%:(P22%
,P32%),S%:(P21%,P41%),S%:(P22%,P42%),Lv1%-1)
       SpinsTC2:(S%:(P21%,P41%),S%:(P22%,P42%),S%:(P21%,P31%),S%:(P22%,P32%),S%:
(P31%,P21%),S%:(P32%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),Lv1%-1)
       SpinsTC2:(S%:(P31%,P11%),S%:(P32%,P12%),S%:(P31%,P21%),S%:(P32%,P22%),P31
%,P32%,S%:(P31%,P41%),S%:(P32%,P42%),Lv1%-1)
       SpinsTC2:(S%:(P11%,P31%),S%:(P12%,P32%),S%:(P21%,P41%),S%:(P22%,P42%),S%:
(P31%,P11%),S%:(P32%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),Lv1%-1)
    ELSE
       POLY3:(P11%,P12%,P31%,P32%,P21%,P22%,2)
    ENDIF
ENDP
REM Carré avec triangle vide en haut à gauche
PROC SpinsTC3:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinsTC3:(S%:(P21%,P11%),S%:(P22%,P12%),P21%,P22%,S%:(P21%,P31%),S%:(P22%
,P32%),S%:(P21%,P41%),S%:(P22%,P42%),Lv1%-1)
       SpinsTC2:(S%:(P21%,P41%),S%:(P22%,P42%),S%:(P21%,P31%),S%:(P22%,P32%),S%:
(P31%,P21%),S%:(P32%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),Lv1%-1)
       SpinskTC:(S%:(P31%,P11%),S%:(P32%,P12%),S%:(P31%,P21%),S%:(P32%,P22%),P31
%,P32%,S%:(P31%,P41%),S%:(P32%,P42%),Lv1%-1)
       SpinsTC3:(S%:(P41%,P21%),S%:(P42%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),S%:
(P31%,P41%),S%:(P32%,P42%),S%:(P41%,P31%),S%:(P42%,P32%),Lv1%-1)
       SpinsTC3:(S%:(P41%,P11%),S%:(P42%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),S%:
(P41%,P31%),S%:(P42%,P32%),P41%,P42%,Lv1%-1)
       SpinsTC3:(S%:(P11%,P31%),S%:(P12%,P32%),S%:(P21%,P41%),S%:(P22%,P42%),S%:
(P31%,P11%),S%:(P32%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),Lv1%-1)
    ELSE
       POLY3:(P21%,P22%,P41%,P42%,P31%,P32%,3)
    ENDIF
ENDP

REM Carré avec triangle vide en haut à droite
PROC SpinsTC4:(P11%,P12%,P21%,P22%,P31%,P32%,P41%,P42%,Lv1%)
    IF Lv1%>0
       SpinsTC4:(P11%,P12%,S%:(P11%,P21%),S%:(P12%,P22%),S%:(P11%,P31%),S%:(P12%
,P32%),S%:(P11%,P41%),S%:(P12%,P42%),Lv1%-1)
       SpinsTC4:(S%:(P31%,P11%),S%:(P32%,P12%),S%:(P31%,P21%),S%:(P32%,P22%),P31
%,P32%,S%:(P31%,P41%),S%:(P32%,P42%),Lv1%-1)
       SpinsTC3:(S%:(P41%,P21%),S%:(P42%,P22%),S%:(P31%,P11%),S%:(P32%,P12%),S%:
(P31%,P41%),S%:(P32%,P42%),S%:(P41%,P31%),S%:(P42%,P32%),Lv1%-1)
       SpinskTC:(S%:(P41%,P11%),S%:(P42%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),S%:
(P41%,P31%),S%:(P42%,P32%),P41%,P42%,Lv1%-1)
       SpinsTC4:(S%:(P11%,P41%),S%:(P12%,P42%),S%:(P11%,P31%),S%:(P12%,P32%),S%:
(P41%,P21%),S%:(P42%,P22%),S%:(P41%,P11%),S%:(P42%,P12%),Lv1%-1)
       SpinsTC4:(S%:(P11%,P31%),S%:(P12%,P32%),S%:(P21%,P41%),S%:(P22%,P42%),S%:
(P31%,P11%),S%:(P32%,P12%),S%:(P41%,P21%),S%:(P42%,P22%),Lv1%-1)
    ELSE
       POLY3:(P11%,P12%,P41%,P42%,P31%,P32%,4)
    ENDIF
ENDP

:

[zpalm]

Beau programme ! Juste une petite remarque pour le tri-carré: tu n’as pas besoin des 4 routines SpinsTC1, SpinsTC2, SpinsTC3 & SpinsTC4. Une seule suffit en jouant avec l’ordre des points lors de l’appel.

Quelle est la vitesse du Psion pour ces figures ? Sur la HP Prime TIME(S_trisquare(5)) donne ~27s.

[Marge]

Et voici le lien entre les triangles de Warclaw Sierpiński et les tours de Hanoi...

https://www.youtube.com/watch?v=rOnRbPKvGQg

Une bonne chaîne !