Ma contribution, le programme "JACK-POT" paru dans le n°135, page 32 (FX-702P)
JACK-POT
Un Jack-pot certes, mais un jack-pot de poche, individuel et portatif...
Thierry LOISEAU (cui, cui)
(dessin de Carali — comme d'habitude
—
http://www.paulcarali.net/ )
Mode d'emploi :
Retirez les piles de votre machine, patientez une trentaine de secondes puis reconnectez l'énergie. Recherchez alors les caractères suivants :
'_°# (Note : # = pavé noir)
placez-les dans $, puis entrez-les respectivement dans A$, B$, C$ et D$.
Tapez le programme.
Pour la première partie, faire :
F1 SAC
100 STAT
Votre but est d'obtenir trois symboles identiques en un minimum de six coups. Vous devrez sans doute pour cela changer un ou plusieurs des trois caractères par appui sur "1" ou (et) "2" ou (et) "3" et valider ensuite par SPC (le témoin à ^).
Si vous n'avez pas appuyé sur ces touches et si le jeu n'affiche pas trois caractères identiques, votre score sera divisé par deux. Dans le cas contraire, ce dernier sera additionné à votre mise multiplié par la valeur de caractère.
Ordre d'importance des caractères :
"$" : 3 fois la mise.
"°" : 2.75 fois la mise.
"π" : 2.5 fois la mise.
"#" : 2.25 fois la mise. (Note : # = pavé noir)
"*" : 2 fois la mise.
"E" : 1.75 fois la mise. (Note : petit E)
"." : 1.5 fois la mise.
"'" : 1 fois la mise.
Lorsqu'elle est supérieure au record précédent, la somme la plus élevée pendant le jeu devient le nouveau.record.
Nota bene :
^ = Flèche vers le haut (puissance)
LIGNE 19 : lire petit E
Ligne 18,100,110,150,500 : idem, caractère petit E correspondant à un *10^
Code : Tout sélectionner
VAR: 26 PRG: 1680
P0: 1420 STEPS
1 GOTO 9
2 "
3 "LOISEAU T.
4 "LA BACHELLERIE
5 "24210 THENON
6 "
9 WAIT 25:PRT "******JACKPOT*****"
10 G=100:PRT CSR 0;"VOUS POSSEDEZ 100 $":M=G
18 $=" BONNE CHANCE .......":GSB 5\E3
19 $=A$+"."+C$+D$+"*$\E\PI"
20 PRT :PRT CSR 6;:INP "MISE ",H:H=INT H: IF H>G THEN 20
21 IF H<1 THEN 20
30 I=INT (RAN#*8)+1:J=INT (RAN#*8)+1:K=INT (RAN#*8)+1
35 V$=MID(I,1):W$=MID(J,1):X$=MID(K,1)
40 FOR O=1 TO 6:PRT CSR 2;#;O;CSR 5;B$;B$;B$;CSR 10;">!";CSR 13;"!";
43 PRT CSR 15;"!";CSR 17;"!<";
47 Q=0:R=0:S=0
50 FOR P=1 TO 4
60 PRT CSR 12;MID(INT (RAN#*8)+1,1);CSR 14;MID(INT (RAN#*8)+1,1);
70 PRT CSR 16;MID(INT (RAN#*8)+1,1);:NEXT P
75 PRT CSR 12;V$;CSR 14;W$;CSR 16;X$;
80 PRT CSR 0;" ";:IF O=6;IF V$=W$;IF W$=X$;O=O-1
85 IF O=6;G=G-H:L=H:FOR O=1 TO 10:NEXT O:PRT :GOTO 140
89 IF KEY="" THEN 89
90 IF KEY="1";PRT CSR 5;V$;:Q=1
91 IF KEY="2";PRT CSR 6;W$;:R=2
92 IF KEY="3";PRT CSR 7;X$;:S=3
93 IF KEY="1";PRT CSR 5;B$;:Q=0
94 IF KEY="2";PRT CSR 6;B$;:R=0
95 IF KEY="3";PRT CSR 7;B$;:S=0
96 IF KEY=" ";PRT CSR 0;"^";:GOTO 100
97 GOTO 89
100 T=Q*1\E2+R*10+S
101 IF T=3;GSB 1000
102 IF T=20;GSB 1001
103 IF T=23;GSB 1000:GSB 1001
104 IF T=100;GSB 1002
105 IF T=103;GSB 1000:GSB 1002
106 IF T=120; GSB 1001:GSB 1002
107 IF T=123;GSB 1000:GSB 1001:GSB 1002
109 PRT CSR 0;
110 N=0:IF T=0;IF V$=W$;IF W$=X$;N=1:GSB 9\E3:GOTO 140
120 IF T=0;G=G/2:PRT "RESTE ";G;" $":IF G<1 THEN 190
130 NEXT O:G=G-H:L=H
140 U$="GAGNE":IF N=0;U$="PERDU"
141 PRT "VOUS AVEZ ";U$;L;" $":IF U$="GAGNE";GSB 9050
150 IF G>1;GOTO 7\E3
190 PRT "RUINE ...."
200 $=" JEU TERMINE ... "
500 GSB 5\E3:WAIT 20:IF M>SX;SAC :STAT M:PRT CSR 5;"RECORD !"
600 PRT CSR 2;"RECORD :";SX;" $":END
1000 K=INT (RAN#*8)+1:X$=MID(K,1):RET
1001 J=INT (RAN#*8)+1:W$=MID(J,1):RET
1002 I=INT (RAN#*8)+1:V$=MID(I,1):RET
5000 FOR I=1 TO LEN($)-6:PRT CSR 6;MID(I,7);
5001 NEXT I:RET
7000 WAIT 25:PRT "VOUS POSSEDEZ";G;" $":GOTO 20
9000 Z=1:IF I=6;Z=3
9001 IF I=3;Z=2.75
9002 IF I=8;Z=2.5
9003 IF I=4;Z=2.25
9004 IF I=5;Z=2
9005 IF I=7;Z=1.75
9006 IF I=2;Z=1.5
9010 L=Z*H
9030 G=G+H*Z
9040 RET
9050 IF G>M;M=G:RET
9060 RET
*** VAR LIST
VAR: 26 PRG: 1680
A$ ='
B$ =_
C$ =°
D$ =#
...
