[HP-41C...] Division. Un essai pas concluant (à deboguer) :(

[Thierry Loiseau]

Il y a un bug

Code : Tout sélectionner

 01 LBL"EUCLID"
 02 FIX 0
 03 CF 29
 04 "DIVIDENDE ?"
 05 PROMPT
 06 STO 11
 07 "DIVISEUR ?"
 08 PROMPT
 09 STO 12
 10 MOD
 11 STO 14
 12 STO 00
 13 RCL 11
 14 RCL 12
 15 /
 16 INT
 17 STO 13
 18 STO 21
 19 XEQ a
 20 1
 21 -
 22 STO 15
 23 RCL 11
 24 XEQ a
 25 STO 16
 26 XEQ b
 27 RCL 11
 28 RCL 12
 29 /
 30 INT
 31 XEQ a
 32 STO 00
 33 RCL 14
 34 STO IND 00
 35 LBL 00
 36 CLA
 37 ARCL 11
 38 "[ I "
 39 ARCL 12
 40 AVIEW
 41 CLA
 42 CF 05
 43 RCL 16
 44 1
 45 +
 46 STO 22

ok

Code : Tout sélectionner

 47 XEQ c

Code : Tout sélectionner

 48 SF 05
 49 "[--"
 50 RCL 12
 51 RCL 13
 52 X<=Y?
 53 X<>Y
 54 XEQ a
 55 STO 22

Code : Tout sélectionner

 56 XEQ c

Code : Tout sélectionner

 57 AVIEW
 58 CF 05
 59 RCL 13
 60 XEQ a
 61 1
 62 X=Y?
 63 GTO 03
 64 STO 15
 65 1
 66 STO 00
 67 LBL 02
 68 CLA
 69 RCL 00
 70 RCL 15 
 71 x=y?
 72 GTO 03
 73 RCL 15
 74 2
 75 -
 76 RCL 00
 77 -
 78 STO 21
 79 RCL IND 00
 80 XEQ a
 81 RCL 21
 82 +
 83 CHS
 84 RCL 16
 85 +
 86 STO 22

Code : Tout sélectionner

 87 XEQ c
 88 ARCL IND 00
 89 RCL 21
 90 STO 22

Code : Tout sélectionner

 91 XEQ c

Code : Tout sélectionner

 92 "[ I "
 93 1
 94 RCL 00
 95 x=y?
 96 ARCL 13
 97 AVIEW
 98 1
 99 ST+ 00
100 GTO 02

Le nombre de chiffres = ok

Code : Tout sélectionner

101 LBL a
102 LOG
103 INT
104 1
105 +
106 RTN

Les restes dans STO n (n à 1) = ok

Code : Tout sélectionner

107 LBL b
108 RCL 21
109 10       
110 /
111 STO 21
112 FRC
113 10
114 *
115 INT
116 STO 19
117 RCL 12
118 *
119 RCL 00
120 +
121 STO 00
122 STO IND 15
123 RCL 00
124 10
125 /
126 INT
127 STO 00
128 1
129 ST- 15
130 RCL 15
131 x≠0?
132 GOTO b
133 RTN

Affiche n espace(s) ou tirets = ok

Code : Tout sélectionner

134 LBL c
135 RCL 22
136 x=0?
137 RTN
138 FC? 05
139 "[ "
140 FS? 05
141 "[-"
142 1
143 ST- 22
144 GTO c

Affiche le reste final : ok

Code : Tout sélectionner

145 LBL 03
146 RCL 14
147 XEQ 04
148 CHS
149 RCL 16
150 +
151 STO 22
152 XEQ c
153 ARCL 14
154 "[ I "
155 RCL 13
156 10
157 X>Y?
158 ARCL 13
159 AVIEW
160 FIX 4
161 SF 29
162 END

Trouverez-vous où mes pas de programmes ont failli avec ce décalage d'un espace devant les restes intermédiaires ?

FX-702P version 1.0

[Thierry Loiseau]

J'ai trouvé

[Thierry Loiseau]

J'ai trouvé

Ah ben non

[cgh]

Le programme recopie ne marche pas ! J'ai une erreur NONEXISTENT a la ligne 147. De plus, en 132 ce n'est GOTO b mais GTO b.
Pourrais-tu refaire une passe sur ton listing ?

[Thierry Loiseau]

Oui, exact ! Une faute de saisie pour le XEQ 04 et en supprimant, ça marche ?
Je reposterai le listing plus tard... (il faut que je retrouve le listing )

[cgh]

Oui, exact ! Une faute de saisie pour le XEQ 04 et en supprimant, ça marche ?
Je reposterai le listing plus tard... (il faut que je retrouve le listing )

Non !
Soit ce n'est pas le bon label pour XEQ soit il manque un LBL 04 quelque part !

[Thierry Loiseau]

Bon, je vais essayer de le ressaisir

En attendant...

[Thierry Loiseau]

Oh là ! J'ai trouvé

Il faut supprimer les lignes 83 & 84 (1 +) et ça semble être ok



v5

[Thierry Loiseau]

Il faut supprimer les lignes 83 & 84 (1 +) et ça semble être ok

Ben non
Ne marche pas si il n'y a pas de reste intermédiaire

Edit : ne marchait pas non plus avant le premier bug...

[Thierry Loiseau]

À mon avis, on repart sur ça (à ajouter à mon précédent listing sans le bug du " 1+"

Code : Tout sélectionner

 58 CF 05
 59 RCL 13
 60 XEQ a
 61 1
 62 X=Y?
 63 GTO 03

Puis affiche le reste final : ok

Code : Tout sélectionner

145 LBL 03
146 RCL 14
147 XEQ a => pas XEQ 04
148 CHS
149 RCL 16
150 +
151 STO 22
152 XEQ c
153 ARCL 14
154 "[ I "
155 RCL 13
156 10
157 X>Y?
158 ARCL 13
159 AVIEW
160 FIX 4
161 SF 29
162 END

Une idée à tester... et réadapter

[cgh]

Voila, ca a l'air de fonctionner

Code : Tout sélectionner

125689 I 7
       -------
 55    I 17955
  66   I 
   38  I 
    39 I 
     4 I 

Le programme (Xz0? c'est X different de 0 et "` c'est le APPEND)

Code : Tout sélectionner

 01¤LBL "EUCLID"
 02 FIX 0
 03 CF 29
 04 "DIVIDENDE ?"
 05 PROMPT
 06 STO 11
 07 "DIVISEUR ?"
 08 PROMPT
 09 STO 12
 10 MOD
 11 STO 14
 12 STO 00
 13 RCL 11
 14 RCL 12
 15 /
 16 INT
 17 STO 13
 18 STO 21
 19 XEQ a
 20 1
 21 -
 22 STO 15
 23 RCL 11
 24 XEQ a
 25 STO 16
 26 XEQ b
 27 RCL 11
 28 RCL 12
 29 /
 30 INT
 31 XEQ a
 32 STO 00
 33 RCL 14
 34 STO IND 00
 35¤LBL 00
 36 CLA
 37 ARCL 11
 38 "` I "
 39 ARCL 12
 40 AVIEW
 41 CLA
 42 CF 05
 43 RCL 16
 44 1
 45 +
 46 STO 22
 47 XEQ c
 48 SF 05
 49 "`--"
 50 RCL 12
 51 RCL 13
 52 X<=Y?
 53 X<>Y
 54 XEQ a
 55 STO 22
 56 XEQ c
 57 AVIEW
 58 CF 05
 59 RCL 13
 60 XEQ a
 61 STO 15
 62 1
 63 STO 00
 64¤LBL 02
 65 CLA
 66 RCL 00
 67 RCL 15
 68 X=Y?
 69 GTO 03
 70 RCL 15
 71 1
 72 -
 73 RCL 00
 74 -
 75 STO 21
 76 RCL IND 00
 77 XEQ a
 78 RCL 21
 79 +
 80 CHS
 81 RCL 16
 82 +
 83 STO 22
 84 XEQ c
 85 ARCL IND 00
 86 RCL 21
 87 STO 22
 88 XEQ c
 89 "` I "
 90 1
 91 RCL 00
 92 X=Y?
 93 ARCL 13
 94 AVIEW
 95 1
 96 ST+ 00
 97 GTO 02
 98¤LBL a
 99 LOG
100 INT
101 1
102 +
103 RTN
104¤LBL b
105 RCL 21
106 10
107 /
108 STO 21
109 FRC
110 10
111 *
112 INT
113 STO 19
114 RCL 12
115 *
116 RCL 00
117 +
118 STO 00
119 STO IND 15
120 RCL 00
121 10
122 /
123 INT
124 STO 00
125 1
126 ST- 15
127 RCL 15
128 Xz0?
129 GTO b
130 RTN
131¤LBL c
132 RCL 22
133 X=0?
134 RTN
135 FC? 05
136 "` "
137 FS? 05
138 "`-"
139 1
140 ST- 22
141 GTO c
142¤LBL 03
143 RCL 14
144 XEQ a
145 CHS
146 RCL 16
147 +
148 STO 22
149 XEQ c
150 ARCL 14
151 "` I "
152 AVIEW
153 END

[Thierry Loiseau]

Voila, ca a l'air de fonctionner

Code : Tout sélectionner

125689 I 7
       -------
 55    I 17955
  66   I 
   38  I 
    39 I 
     4 I 

Et 125689 / 125680, ça donne quoi ?

[Thierry Loiseau]

Voilà !

J'en ai profité pour allonger les deux barres (c'est plus joli)

version 6


Reste plus qu'à reprogrammer et optimiser, parce que, devoir utiliser 23 registres

En gros :

Code : Tout sélectionner

Exemple

125689 I 7
       --------
 55    I 17955
  66   I  
   38  I
    39 I
     4 I

STO 11 = 125689 : dividende
STO 12 =      7 : diviseur
STO 13 =  17955 : quotient
STO 14 =     [4]: reste final

STO 00 =      4 restes à afficher (c-à-d correspond aux 5 chiffres présentant le quotient - 1)
STO 01 =     55
STO 02 =     66
STO 03 =     38
STO 04 =     39
---------------------
Pour déterminer les restes intermédiaires,  on part du reste final, [4] 
et on décompose les chiffres du quotient de droite à l'avant-dernier à gauche.
Il n'y a reste intermédiaire que si le quotient comporte au moins 2 chiffres, donc > 9

Soit

4) 5 * 7 = 35 => 35 + [4] = [39] ; on traite ce dernier reste en supprimant son unité {3.9 => 3}
3) 5 * 7 = 35 => 35 + {3} = [38] ; {3.8 => 3}
2) 9 * 7 = 63 => 63 + {3} = [66] ; {6.6 => 6} 
1) 7 * 7 = 49 => 49 + {6} = [55] ; {5.5 => 5}
---------------------
0) 1 * 7 =  7 =>  7 + {5} = [12]... en fait, les premiers chiffres du dividende [12]5689 !
---------------------
Pour les décalages (nbre d'espaces) à droite du reste :
1er reste intermédiaire : 0 (tout comme le reste final)
2e : 1
3e : 2
4e : 3

Nbre d'espace devant le reste intermédiaire =
longueur du dividende - longueur du reste - décalage à droite du reste
---------------------
LBL 02 : Traite et affiche chacun des restes intermédiaires du premier, en haut, au dernier
LBL a   : Détermine le nbre de chiffre
LBL b   : Déterminer tous les restes intermédiaires et stocke depuis STO 01  à STO n
LBL c   : Affichage de x espaces (depuis STO 22)
LBL d    : Affiche le début de la division : 125689 I 125
                                                    -------
LBL d   : Appelé dans le programme pour traiter les restes intermédiaires et dans le cas d'un seul reste, appelé par le LBL e             
LBL e   : affichage des espaces avant la barre horizontale puis LBL 03
LBL 03  : Fin de la division  avec affichage du dernier reste
STO 00  : RESTE INTERMEDIAIRES CALCULE
STO 01 à STO 10 : Restes intermédiaires
STO 11  : DIVIDENDE                          125689
STO 12  : DIVISEUR                              125
STO 13  : QUOTIENT (ENTIER)                    1005
STO 14  : RESTE                                  64
STO 15  : NOMBRE DE CHIFFRE DU QUOTIENT -1 = 3 => Nombre de reste intermédiaire
STO 16  : NOMBRE DE CHIFFRE DU DIVIDENDE     6
STO 17  : Nbre d'espace devant le reste
STO 18  : Nbre d'espace devant le reste / après le reste
STO 19  : Chiffre du quotient à traiter
STO 20  : Nombre de chiffre du quotient traité
STO 21  : QUOTIENT réduit d'unité en unité
STO 22  : Nbre d'espace / tiret à afficher  pour l'appel du LBL c

liste pas forcément conforme au dernier listing....

[Thierry Loiseau]

Bon, il y a manière à améliorer tout de même au niveau de la formulation...

Code : Tout sélectionner

125689 I 256
       ------
 2328  I 490
   249 I
   249 I
       I

Il faudrait donc plutôt chercher à décomposer et présenter de cette manière :

Option 1

Code : Tout sélectionner

====
125689 I 256
       ------
 232   I 490
 2328  I
   24  I
   249 I
       I

ce qui paraît plus cohérent...

De ce que j'écrivais :

Code : Tout sélectionner

125689 I 7
       --------
 55    I 17955
  66   I 
   38  I
    39 I
     4 I

Soit

4) 5 * 7 = 35 => 35 + [4] = [39] ; on traite ce dernier reste en supprimant son unité {3.9 => 3}
3) 5 * 7 = 35 => 35 + {3} = [38] ; {3.8 => 3}
2) 9 * 7 = 63 => 63 + {3} = [66] ; {6.6 => 6}
1) 7 * 7 = 49 => 49 + {6} = [55] ; {5.5 => 5}
---------------------
0) 1 * 7 =  7 =>  7 + {5} = [12]... en fait, les premiers chiffres du dividende [12]5689 !
---------------------

Il faudrait donc inclure les nombres {n}

Ce qui pourrait donner, en précisant le point de départ (ici, 12 surligné) :

Code : Tout sélectionner

==
125689 I 7
       --------
 5     I 17955
 55    I
  6    I
  66   I
   3   I
   38  I
    3  I
    39 I
     4 I
       I

On retrouve les {3,3,6,5}... Ça ne devient pas très lisible... quoique
une solution encore serait de souligner le reste final si et seulement si il existe un précédent qui lui est égal.

Option 2

Code : Tout sélectionner

====
125689 I 256
       ------
 2328  I 490
   249 I
   249 I
   --- I

ou autre exemple :

Code : Tout sélectionner

===
122512 I 25
       -------
 225   I 4900
    1  I
    12 I
    12 I
    -- I

Ou encore, simplement, ne pas afficher le reste final si il est égal au reste précédent (s'il existe) :

Option 3

Code : Tout sélectionner

122512 I 25
       -------
 225   I 4900
    1  I
    12 I
       I

125689 I 256
       ------
 2328  I 490
   249 I
       I

Et ben, encore du pain sur la planche... mais je crois que je vais d'abord tenter l'option 3

[Thierry Loiseau]

Ou encore, simplement, ne pas afficher le reste final si il est égal au reste précédent (s'il existe) :

Option 3

Code : Tout sélectionner

122512 I 25
       -------
 225   I 4900
    1  I
    12 I
       I

125689 I 256
       ------
 2328  I 490
   249 I
       I

Et ben, encore du pain sur la planche... mais je crois que je vais d'abord tenter l'option 3

Donc... Je n'affiche pas le dernier reste intermédiaire s'il est égal au reste final

Était

Code : Tout sélectionner

 83 1
 84 ST+ 00
 85 GTO 02
 86 LBL a

et maintenant

Code : Tout sélectionner

 83 1
 84 ST+ 00
 85 RCL 00
 86 1
 87 +
 88 RCL 15
 89 X≠Y?
 90 GTO 02
 91 RCL IND 00
 92 RCL 14
 93 X≠Y?
 94 GTO 02
 95 1    
 96 ST+ 00 
 97 CLA
 98 GTO 03
 99 LBL a 

Ça semble marcher...

Version 7 option 3


Y'a plus qu'à trouver un exemple de deux uniques restes égaux... et je suis certain que ça ne passe pas