[FX-702P] La division euclidienne pour les nuls

[Thierry Loiseau]

J'ai retrouvé dans mes archives ce programme génial que j'ai écrit il y a bien 30 ans...



... et cela fonctionne bien



La preuve :



(bon, question optimisation... )

Mais tout de même, 30 ans, c'est émotionnant, non ?



__________________________________________________

... et j'en profite pour faire une petite pub :
__________________________________________________



... bientôt en librairie

[Miskatonic91]

Bravo pour ces reliques du passé, enfin retrouvées! Effectivement, trente ans après, ce doit être émouvant de remettre la main dessus.
Perso, je n'ai rien gardé de cette période, je reprends tout à zéro (pockets, programmation...).
Félicitations pour ton bouquin. Je ne savais pas que "Pour les Nuls" publiait des fascicules consacrés à un seul exercice de maths?

[ledudu]

Salut
Tu nous fais un wav ?
Merci

[badaze]

Bravo pour ces reliques du passé, enfin retrouvées! Effectivement, trente ans après, ce doit être émouvant de remettre la main dessus.
Perso, je n'ai rien gardé de cette période, je reprends tout à zéro (pockets, programmation...).
Félicitations pour ton bouquin. Je ne savais pas que "Pour les Nuls" publiait des fascicules consacrés à un seul exercice de maths?

Il existe des générateurs de couvertures...

[Thierry Loiseau]

Félicitations pour ton bouquin. Je ne savais pas que "Pour les Nuls" publiait des fascicules consacrés à un seul exercice de maths?

Euh, félicitations pour mon "fake" ?

Salut
Tu nous fais un wav ?
Merci

Why not ?

Il existe des générateurs de couvertures...

Vraiment obligé d'utiliser un "générateur de couvertures" pour faire ça ?

[Miskatonic91]

Félicitations pour ton bouquin. Je ne savais pas que "Pour les Nuls" publiait des fascicules consacrés à un seul exercice de maths?

Euh, félicitations pour mon "fake" ?

Ben oui, il est bien fait...

[badaze]

Il existe des générateurs de couvertures...

Vraiment obligé d'utiliser un "générateur de couvertures" pour faire ça ?

Vu qu'ils existent autant les utiliser.

[Thierry Loiseau]

Il existe des générateurs de couvertures...

Vraiment obligé d'utiliser un "générateur de couvertures" pour faire ça ?

Vu qu'ils existent autant les utiliser.

Je ne savais pas... que tu utilisais régulièrement les divisions euclidiennes

[badaze]

Il existe des générateurs de couvertures...

Vraiment obligé d'utiliser un "générateur de couvertures" pour faire ça ?

Vu qu'ils existent autant les utiliser.

Je ne savais pas... que tu utilisais régulièrement les divisions euclidiennes

Je suis comme M. Jourdain qui faisait de la prose sans le savoir.

[spacemax]

C'est un programme sympa que l'on peut utiliser avec les enfants quand ils apprennent les divisions.
Je garde.

[Tipoucet]

Superbe ce programme visuel de division !! j'adore !

[ledudu]

Voici le code :

Code : Tout sélectionner

DEFM 10
10 VAC:WAIT 0:INP "DIVIDENDE=",A,"DIVISEUR",B
20 IF B=0 THEN 10
30 A=INT A:B=INT B:C=INT(A/B):D=A-C*B
40 IF A<B THEN 10
50 E=1:IF C<=0;E=2
60 FOR I=2 TO 9:IF C>=10^I;E=I+1:NEXT I:GOTO 90
70 NEXT I
80 MODE 7
90 F=1:IF A>=10;F=2
100 FOR I=2 TO 9:IF A>=10^I;F=I+1:NEXT I:GOTO 120
110 NEXT I
120 G=4:IF B>=10;G=5
130 FOR I=2 TO 9:IF B>=10^I;G=I+4:NEXT I:GOTO 130
140 NEXT I
150 PRT A;" !";B:FOR I=1 TO G:$=$+"-":NEXT I
160 PRT CSR F+2;$
170 FOR I=E TO 1 STEP-1:A(I)=FRAC(C/10^I):A(I)=A(I)*10
180 A(I)=INT A(I):NEXT I
190 J=A
200 IF A(E)*B<J;J=J/10:GOTO 200
210 J=J*10:H=2:IF J>=10;H=3
220 FOR I=2 TO 9:IF J>=10^I;H=I+2:NEXT I:GOTO 260
230 NEXT I
240 K=INT J-A(E)*B:L=E:IF J=A;M=1
250 IF M!=1;K=K*10:N=J*10:N=INT N/10:N=FRAC N:N=N*10:K=K+N
260 L=L-1
270 H=H+1
280 T=E:J=J*10
290 IF E=1;H=F+1:K=D
300 IF H=1;PRT#;K;
310 IF H=2;PRT##;K;
320 IF H=3;PRT###;K;
330 IF H=4;PRT####;K;
340 IF H=5;PRT#####;K;
350 IF H=6;PRT######;K;
360 IF H=7;PRT#######;K;
370 IF H=8;PRT########;K;
380 IF H=9;PRT#########;K;
390 IF H=10;PRT##########;K;
400 IF L+1=E;PRT CSR F+2;"!";C
410 IF L+1!=E;PRT CSR F+2;"!"
420 IF E=1;PRT:PRT:PRT:PRT:MODE 8:END
430 E=E-1:O=A(E)*B:K=K-O:J=J*10:P=INT J/10:K=K*10:P=FRAC P
440 P=P*10:K=K+P:H=H+1
450 IF E=1;K=K/10
460 GOTO 290

[jojo]

Pour le fun, j'ai essayé en GW-Basic (DosBox sous Linux) ... Ya des trucs qui ne marchent pas !
CSR qui n'a pas d'équivalent en GW-Basic par exemple ou bien la fonction INT qui ne renvoie que l'entier le plus petit et pas le plus proche (FIX, CINT ou CLNG ne donnent pas les bons résultats) ou encore la fonction FRAC qui n'existe pas ..

Alors, le programme devient ça, après mûre réflexion et avec obligation de passer en double précision sinon l'affichage avec de grands nombres devient incohérent à cause de ^E. Et puis, je me suis aussi amusé à réduire l'affichage des résultats intermédiaires dans une seule boucle sans faire les tests sur la longueur du nombre

Code : Tout sélectionner

100 ' Division Euclidienne
110 ' NCDE: Nombre de chiffres du dividende
120 ' NCDR: Nombre de chiffres du diviseur
130 ' NCQT: Nombre de chiffres du quotient
140 CLS:INPUT "Dividende:",DIVID#
150 IF DIVID#<1 THEN END  'Ça suffit, on a assez fait mumuse !
160 INPUT "Diviseur:",DIVIS#
170 IF DIVIS#=0 OR DIVID#<DIVIS# THEN GOTO 100
180 DIVID#=INT(DIVID#)
190 DIVIS#=INT(DIVIS#)
200 QUOT#=INT(DIVID#/DIVIS#)
210 REST#=DIVID#-(DIVIS#*QUOT#)
220 PRINT:PRINT
230 PRINT DIVID#;"divise par";DIVIS#;"=";QUOT#;"reste ";REST#
240 NCQT=1
250 IF QUOT#>=10 THEN NCQT=2
260 FOR I=2 TO 9
270    IF (10^I)<QUOT# THEN NCQT=I+1 ELSE GOTO 290
280 NEXT I
290 NCDE=1
300 IF DIVID#>=10 THEN NCDE=2
310 FOR I=2 TO 9
320    IF (10^I)<DIVID# THEN NCDE=I+1 ELSE GOTO 340
330 NEXT I
340 NCDR=4
350 IF DIVIS#>=10 THEN NCDR=5
360 FOR I=2 TO 9
370    IF (10^I)<DIVIS# THEN NCDR=I+4 ELSE GOTO 390
380 NEXT I
390 FOR I=NCQT TO 1 STEP -1
400    CHIF#(I)=INT((QUOT#/(10^I)-INT(QUOT#/(10^I)))*10+1*(10^-I)) ' l'ajout de 1*(10^-I) c'est pour forcer INT à renvoyer le bon résultat
410 NEXT I
420 PRINT:PRINT
430 RESU#=DIVID#
440 U$=STRING$(NCDE+NCDR-2,"#")
450 PRINT USING U$;RESU#;
460 PRINT " |";DIVIS#
470 PRINT SPC(NCDE+NCDR-1);"|";STRING$(NCQT+2,"-")
480 FOR I=NCQT TO 2 STEP -1
490    PROD#=DIVIS#*CHIF#(I)*(10^(I-1))
500    RESU#=RESU#-PROD#
510    U$=STRING$(NCDE-I+NCDR,"#")
520    PRINT USING U$;INT(10*(RESU#/(10^(I-1))));
530    PRINT SPC(I-1);"|";
540    IF I=NCQT THEN PRINT QUOT# ELSE PRINT
550 NEXT I
560 I=1
570 PROD#=DIVIS#*CHIF#(I)*(10^(I-1))
580 RESU#=RESU#-PROD#
590 U$=STRING$(NCDE-2+NCDR,"#")
600 PRINT USING U$;INT((RESU#/(10^(I-1))));
610 PRINT SPC(I);"|";
620 IF NCQT<2 THEN PRINT QUOT#
630 PRINT:PRINT
640 PRINT:PRINT "Appuyez sur une touche"
650 Z$=INPUT$(1)
660 IF Z$=CHR$(27) THEN END 'Ça suffit, on a assez fait mumuse !
670 GOTO 100

Si quelqu'un veut bien essayer ... pour voir s'il ne reste pas un ou deux bugs.
J'ai fait la même chose pour QBasic mais sans les numéros et en utilisant la sortie de boucle avec EXIT FOR. Il y a aussi la possibilité de créer la fonction Frac. Je peux mettre cette version QBasic à disposition.

[Marge]

Moi, en tout cas, ça me donne bien envie d'essayer sur HP-19c ou HP-97... MPO !

... et sur un Sharp 1403 pour la beauté de l'impression.

[Thierry Loiseau]

Bravo à vous pour les retranscriptions !
À l'époque, je ne connais pas la possibilité d'utiliser la fonction Log pour déterminer le nombre de chiffres composant un nombre entier.

Par exemple quelque chose comme cela :

Code : Tout sélectionner

10 INP "NOMBRE :",N
20 C=INT(LOG(N))+1
30 PRT "NOMBRE DE CHIFFRES :";C

D'autre part, la fonction "INT" retourne la partie entière ; "FRAC" la partie décimale.
De plus, la ligne

Code : Tout sélectionner

280 T=E:J=J*10

doit se simplifier par

Code : Tout sélectionner

280 J=J*10

(la variable T ne servant que de repère pour débuguer le programme...