Voici une solution qui ne demande qu'un PC-1500 et va vous permettre d'enregistrer 255 temps.
Sa mise en oeuvre est simple mais nécessitera quand même un démontage du PC-1500
afin de souder deux petits fils sur les connexions de la touche ON.
(faire la soudure sur le verso pour ne pas gêner l'utilisation normale du clavier)
Ceci fait, vous pouvez relier les autres extrémités des deux fils à un interrupteur ILS.
Un ILS est un Interrupteur à Lame Souple qui est sensible aux champ magnétique.
Même un petit aimant suffit pour assurer un contact. Faites attention en manipulant
l'ILS, c'est une capsule de verre alors faites une torsion des extrémités avec une petite
pince pour ne pas exercer de tension sur la capsule, elle casserait facilement.
D'autre part vous isolerez la transmission thermique de la soudure par un même pincement.
Ensuite vous entrez le programme ci-dessous dans le PC-1500.
(les caractère sont à taper en majuscules. j'ai utilisé les minuscules pour en faciliter la lecture)
Le fonctionnement est simple :
une fois le programme saisi, tapez RUN "INI" pour initialiser les variables.
a cette occasion le programme vous demandera un code d'initialisation.
(ici le password est OEUF programmé en ligne 160 vous pouvez le changer
mais en 1664 une personne l'a changé et on ne l'a jamais retrouvée)
Le programme est maintenant prêt à fonctionner. Eteignez le PC-1500.
A chaque fois que l'interrupteur sera enclenché, le PC enregistrera la valeur
de TIME puis s’éteindra aussitôt, assurant ainsi une bonne autonomie.
Lorsque vous souhaitez interroger le tableau de valeurs, appuyez sur ON en gardant le doigt dessus.
Le PC-1500 vous donnera la main alors vous pourrez taper sur DEF S
Les touches suivantes vous permettent de parcourir le tableau:
+:donnée suivante
- : donnée précédente
D : supprimer la donnée courante (avec confirmation par ENTER)
I : initialiser tout le tableau de valeurs (avec confirmation par password)
Q:quitter (en gardant le PC-1500 allumé)
Une temporisation dans ce menu lui permet d’éteindre automatiquement
le PC-1500 afin de le laisser en mode de surveillance.
Vous pouvez changer la valeur de cette temporisation en ligne 50.
Exemples d'application :
* surveillance d'ouverture de portail, de porte, de tiroirs, de cave...
* surveillance d'accès à une cabane de jardin, un chalet, un abri de chasse, un coffre...
* surveillance de décrochage de téléphone filaire
* surveillance de boite aux lettres
La connaissance des temps enregistrés permet de connaitre :
- la fréquence de l’événement (combien de fois par jour/semaine/etc...)
- la position temporelle de l’évènement (à quelle(s) heure(s), quel jour...)
Ces deux renseignements peuvent vous permettre d'influer l'origine de l’évènement
directement ou indirectement, ou encore de déterminer une conséquence.
Il peut être intéressant d'agir au niveau d'une conséquence car cela évite
la neutralisation du dispositif.
En remplaçant l'interrupteur ILS par une cellule photoélectrique et un montage
vous pouvez obtenir un capteur de lumière. De même vous pouvez imaginer
bien d'autres capteurs à condition d'avoir un bon niveau en électronique.
Il est également possible de monter un mini jack afin d'avoir une meilleure
ergonomie. Afin de ne pas altérer le PC-1500 je conseille d'assurer la fixation
par une pointe de colle silicone à chaud, procédé facilement réversible.
Le programme est adaptable à d'autres modèles SHARP à condition:
- de disposer de la commande ARUN
- de connaitre le Call d'extinction équivalent à Call &CD71 du PC1500.
Code : Tout sélectionner
10 arun
20 t(i)=time:i=i+1:call &cd71
30"S"wait 0:m=0
40 print "t(";j;")=";t(j)
50 k$=inkey$:if k$="" let m=m+1:if m>1000 let m=0:call&cd71
60 if k$="" then 50
65 m=0:if k$="Q" end
70 if k$="+" let j=j+1:if j>i let j=i
80 if k$="-" let j=j-1: if j<0 let j=0
90 if k$="I" then 150
100 if k$="D" then 200
110 goto 40
150 "INI" input "Code initialisation?";a$
160 if a$<>"OEUF" pause "Annuled":goto 40
170 input "Confirmez";a$
180 clear:dim t(255)
190 call &cd71
200 input"Confirmez destruction";a$
205 print "Destruction en cours"
210 for k=j to i : t(k)=t(k+1):next k
215 if i>0 let i=i-1
220 goto 40
