A "Indiana Jones" sur Canon X-07

Les derniers trucs auxquels vous avez joué, les derniers ordinateurs que vous avez bidouillés.

Modérateur : Politburo

Avatar du membre
leglatin
Fonctionne à 1200 bauds
Fonctionne à 1200 bauds
Messages : 761
Enregistré le : 03 févr. 2003 19:46
Localisation : Berville-sur-Mer (27)
Contact :

A "Indiana Jones" sur Canon X-07

Message par leglatin »

Image Image

Déniché dans un Hebdogiciel, le n° 83 du 17 mai 1985 pour être précis (*), voilà un petit jeu comme je les aime !
Elégant tout en étant sobre, aisément jouable sans être trop facile, et au règles simples tout en étant prenant :ugeek: .

(*) merci aux équipes d'Abandonware Magazines et d'Hebdogiciel, les listings pour sa mise à disposition sur le Net 8) .
Commodore 7970 - Texas Instruments TI-30, 57, 60, 66, 74, 76.fr, 80, 81, 82, 82 Stats.fr, 83, 85, 86, 89, 92 - Casio PB-100, PB-110, PB-410, PB-500, PB-700, PB-770, FX-180Pv, FX-7500G, FC-200, FA-3, FA-4, FA-5, FA-10, FA-11, FA-20, FP-12, CM-1, OR-1, OR-1(E), OR-4, OR-8, RC-2, RC-4 - Canon X-07 - Psion Series 5 mx - PalmOne Tungsten E2 - Compaq iPAQ H3900 - HP iPAQ HX2110 - Philips VG8020, NMS8255, VY0010, VY0011, VS0080, D6450, VW0030, SBC3810, NMS1112, NMS1150, NMS1170 - Atari 1040 STE
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

Salut,
Top !
Tu peux uploader le .wav (ou le .txt) ?
J'y jouerai bien sur ma télé avec mon x-720 que je me la pète avec...
Je le publierai là si tu es d'accord : https://canonx07.ledudu.com
Merci,
Avatar du membre
Marge
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 6172
Enregistré le : 01 oct. 2008 14:39
Localisation : En bas, tout au fond à gauche.

Re: A "Indiana Jones" sur Canon X-07

Message par Marge »

Excellent !
Et en effet, il faut encore remercier ceux sans lesquels tout cela ne serait possible : les Aventuriers de l’Archive Perdue !
3 hommes, 3 demis, un 3a... Magnéto, Serge !

Quelques-uns de mes petits programmes pour machines Hewlett-Packard :
15C : Knight's Tour ;
29C : (k-)Permutations, Combinations, Linear Regression and Pseudo-random number ;
34C : Hanoi Towers - Automatic & Manual resolutions ;
67
__: A L I E N .

« Boris », c'était juste Maurice enrhumé.
Avatar du membre
leglatin
Fonctionne à 1200 bauds
Fonctionne à 1200 bauds
Messages : 761
Enregistré le : 03 févr. 2003 19:46
Localisation : Berville-sur-Mer (27)
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par leglatin »

Voilà : IndianaJones :D .
ledudu a écrit :Je le publierai là si tu es d'accord : https://canonx07.ledudu.com
Ce n'est pas moi qui en détient les droits...
Commodore 7970 - Texas Instruments TI-30, 57, 60, 66, 74, 76.fr, 80, 81, 82, 82 Stats.fr, 83, 85, 86, 89, 92 - Casio PB-100, PB-110, PB-410, PB-500, PB-700, PB-770, FX-180Pv, FX-7500G, FC-200, FA-3, FA-4, FA-5, FA-10, FA-11, FA-20, FP-12, CM-1, OR-1, OR-1(E), OR-4, OR-8, RC-2, RC-4 - Canon X-07 - Psion Series 5 mx - PalmOne Tungsten E2 - Compaq iPAQ H3900 - HP iPAQ HX2110 - Philips VG8020, NMS8255, VY0010, VY0011, VS0080, D6450, VW0030, SBC3810, NMS1112, NMS1150, NMS1170 - Atari 1040 STE
Avatar du membre
phm
Fonctionne à 2400 bauds
Fonctionne à 2400 bauds
Messages : 1361
Enregistré le : 08 avr. 2016 18:36
Localisation : Est Parisien

Re: A "Indiana Jones" sur Canon X-07

Message par phm »

Ledudu, j'aimerai bien voir ce que cela donne sur écran :D
HEWLETT-PACKARD : The best
CANON
X-07 X-730 X-711 XR-100 XM-101 XP-110F XP-120F XP-130F XP-140

AMSTRAD CPC-464 CPC-6128 ATARI STF DAI Indata
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

C'est dans la boite,
merci,
phm a écrit : 06 déc. 2021 18:09 Ledudu, j'aimerai bien voir ce que cela donne sur écran :D
C'est prévu :)
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

leglatin a écrit : 06 déc. 2021 16:27 Voilà : IndianaJones :D .
C'est dans la boite,
merci,
leglatin a écrit : 06 déc. 2021 16:27 Ce n'est pas moi qui en détient les droits...
Certes mais je respecte toujours le travail d'aujourd'hui comme celui d'hier.
phm a écrit : 06 déc. 2021 18:09 Ledudu, j'aimerai bien voir ce que cela donne sur écran :D
C'est prévu :)
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

Bon voici déjà le programme d'origine en bas :

Code : Tout sélectionner

Program: IJones

1 '***************
2 '*INDIANA JONES*
3 '***************
4 '** COPYRIGHT **
5 'BAUDET STEPHANE
6 '***************
7 '
8 'introduction &
9 'graphismes...
10 CLS:GOSUB 6000
15 CLEAR 200
99 'crœation caractšres
100 FONT$(128)="0,48,120,48,124,176,40,72"
110 FONT$(129)="0,48,120,48,248,52,80,72"
120 FONT$(130)="0,24,60,24,60,112,160,64"
130 FONT$(131)="0,48,120,48,240,56,20,8"
140 FONT$(132)="0,0,0,0,0,0,80,40"
150 FONT$(133)="0,0,0,0,0,0,40,80"
160 FONT$(134)="252,252,252,252,252,56,16,0"
170 FONT$(135)="252,252,252,124,60,40,0,0"
180 FONT$(136)="252,248,112,48,32,0,0,0"
190 FONT$(137)="136,220,252,248,252,252,252,248"
200 FONT$(138)="60,124,252,252,252,124,252,252"
210 FONT$(139)="140,220,252,252,252,252,252,252"
220 FONT$(140)="252,252,252,252,252,252,252,252"
230 FONT$(141)="252,252,188,56,48,16,16,16"
240 FONT$(142)="16,16,16,32,32,32,64,64"
250 FONT$(143)="16,104,248,104,120,100,124,4"
260 FONT$(144)="16,84,84,56,124,40,68,68"
270 FONT$(145)="16,16,16,16,16,16,16,16"
280 FONT$(146)="252,0,252,252,252,252,252,252"
290 FONT$(148)="16,16,16,8,8,8,4,4"
300 FONT$(150)="16,16,16,32,32,32,64,64"
310 FONT$(149)="16,104,248,104,120,100,124,4"
320 FONT$(147)="0,0,96,240,96,120,100,124"
330 FONT$(224)="252,252,108,16,16,42,16,16"
340 FONT$(225)="128,128,192,224,240,248,252,252"
350 FONT$(226)="0,4,4,0,4,12,4,4"
360 FONT$(227)="0,128,128,128,128,192,128,128"
370 FONT$(228)="4,4,12,28,60,124,252,252"
380 FONT$(229)="0,0,12,16,32,64,128,128"
390 FONT$(230)="0,0,192,32,16,8,4,4"
400 FONT$(231)="128,128,64,32,16,12,0,0"
410 FONT$(232)="4,4,8,16,32,192,0,0"
500 'crœation dœcor
510 FOR P=0 TO 19:READ PL:P$=P$+CHR$(PL):NEXT P
550 T$=CHR$(137)+" "+CHR$(138)
560 F$=CHR$(137)+"    "+CHR$(138)
570 S$=CHR$(140)+CHR$(139)+CHR$(140)+CHR$(140)
580 D$=CHR$(140)+CHR$(146)+CHR$(140)+CHR$(146)
690 SOL$(0)=CHR$(140)+CHR$(140)+T$+S$+S$+T$+T$
700 SOL$(1)=S$+T$+S$+S$+T$+CHR$(139)
710 SOL$(2)=S$+T$+T$+CHR$(139)+F$+CHR$(140)+CHR$(139)
720 SOL$(3)=T$+S$+S$+T$+CHR$(140)+CHR$(139)+T$
730 SOL$(4)=S$+T$+T$+CHR$(140)+CHR$(139)+D$+T$
740 SOL$(5)=S$+D$+CHR$(139)+D$+S$+CHR$(139)+CHR$(140)
900 DATA 13,135,135,136,134,136,141,141,134,135,224,136,141,141
910 DATA 141,141,134,134,135,136
1000 '============
1001 'affich.tabl.
1002 '============
1003 '
1010 CLS:T=1:H$=CHR$(128):X=1:RE=1
1011 CA=1:M=1:N=1
1012 TIME$="00:00:00"
1100 CLS:LOCATE 0,0:PRINTP$;
1150 DE=INT(RND(1)*4+1):RU=INT(RND(DE)*4+1)
1200 IF T<1 AND ET=0 THEN IF D=1 THEN 7000 ELSE 1010
1210 LOCATE 0,3:PRINTSOL$(T);
1220 IF DE=RU AND ET=0 AND T<>1 THEN LOCATE 10,3:PRINT" ";
1250 FOR I=1 TO 6:LINE(113+I,24)-(113+I,31):NEXT I
1500 '=============
1501 '=dœplacement=
1502 '=============
1503 '
1520 GOSUB 1900:GOSUB 1910:LOCATE X,2:PRINTH$;
1550 TT$=INKEY$
1600 IF TT$=CHR$(28) AND X<20 THEN SC=SC+RE:GOTO 2100
1650 IF TT$=CHR$(29) AND X>0 THEN SC=SC-RE:GOTO 2200
1660 IF TT$=CHR$(30) THEN 2300
1800 GOSUB 3000:GOSUB 4000:GOTO 1520
1900 IF X>=19 AND H$=CHR$(128) THEN T=T+1:PRINT" ";:X=0:GOTO 1100 ELSE RETURN
1910 IF X<=0 AND H$=CHR$(129) THEN T=T-1:X=18:GOTO 1100 ELSE RETURN
2000 '============
2001 'result.depl.
2002 '============
2003 '
2100 LOCATE X,2:PRINT" ";:X=X+1:H$=CHR$(128):GOSUB 3000:GOTO 1520
2200 LOCATE X,2:PRINT" ";:X=X-1:H$=CHR$(129):GOSUB 3000:GOTO 1500
2300 IF H$=CHR$(129) THEN 2400
2350 LOCATE X,2:PRINT" ";:LOCATE X+1,1:PRINTCHR$(130);:FOR I=1 TO 50:NEXT I
2355 SC=SC+(RE*5)
2360 LOCATE X+1,1:PRINT" ";:X=X+2:IF X>18 THEN X=0:T=T+1:GOTO 1100: ELSE GOSUB 3000
2370 GOTO 1500
2400 LOCATE X,2:PRINT" ";:LOCATE X-1,1:PRINTCHR$(131);:FOR I=1 TO 50:NEXT
2420 SC=SC-(RE*5)
2450 LOCATE X-1,1:PRINT" ";:X=X-2:IF X<0 THEN X=19:T=T-1:GOTO 1100: ELSE GOSUB 3000
2500 GOTO 1500
3000 '==============
3001 '=== pišges ===
3002 '==============
3004 '
3100 IF ID=1 AND T<>0 THEN GOSUB 3700
3150 ON T+1GOSUB 3170,3200,3300,3400,3500,3600
3160 GOTO 3900
3165 IF ID=1 THEN GOSUB 3700
3170 'descente
3180 IF X<2 THEN X=2
3190 RETURN
3200 'serpents
3210 IF X=(15+SE) OR X=(5-SE) THEN SD=1:GOTO 5000
3220 IF ID=1 AND X<16 AND X>=(18-BO) THEN 5000
3290 RETURN
3300 'fossœ
3310 IF X>11 AND X<16 AND X=(-M*1+(12+(M*LI))) THEN 4320
3390 RETURN
3400 'araignœes
3410 IF X=6 AND AA=1 THEN SD=1:GOTO 5000
3420 IF X=7 AND AA=0 THEN SD=1:GOTO 5000
3490 RETURN
3500 'dalles
3510 FOR D=0 TO 2 STEP 2:IF X=(12+(AA+D)) THEN 4120 ELSE NEXT D
3520 IF X>1 AND ET=0 THEN T=INT(RND(1)*3+1)
3590 RETURN
3600 'idole
3610 IF X>13 THEN FONT$(128)="0,48,120,48,252,240,40,72":H$=CHR$(129): ELSE 3640
3620 FONT$(129)="0,48,120,48,252,60,80,72":FONT$(227)="0,0,0,0,0,192,128,128"
3630 FONT$(226)="0,0,0,0,0,12,4,4":X=14:ID=1:RE=-1:RETURN
3640 IF ID=1 AND(X=6+AA OR X=12+AA) THEN 4120
3650 RETURN
3700 'rien ‰ voir
3710 ZZ=ZZ+.04:IF ZZ>20 THEN ZZ=20
3715 LINE(21,24)-(21,24-ZZ)
3720 IF X=3 AND ZZ>5 THEN X=X+1:LOCATE 3,2:PRINT" ";
3721 IF X=2 AND ZZ>12 THEN X=X+2
3730 RETURN
3900 '
3910 IF X>0 AND X<19 AND X<>10 THEN IF SCREEN(X,3)=32 THEN GOTO 5000
3915 IF X=10 AND SCREEN(10,3)=32 THEN 8000
3920 RETURN
4000 '=============
4001 '==action(p)==
4002 '=============
4003 '
4010 ON T+1GOTO 4500,4400,4300,4200,4100,4050
4050 ' @@ idole @@
4060 LOCATE 15,2:PRINTCHR$(226);:LOCATE 16,2:PRINTCHR$(227);
4075 LOCATE 19,1:PRINTCHR$(228);:LOCATE 18,2:PRINTCHR$(228);:LOCATE 19,2:PRINTCHR$(140);
4090 RETURN
4100 ' @@ dalles @@
4110 RETURN
4120 LOCATE X,2:PRINTH$
4121 IF INKEY$<>"" THEN 1550
4122 FOR I=2 TO 20:PRESET(X*6+3,I):PSET(X*6+3,I+1):PSET(X*6+3,I+2):BEEP I,1:NEXT I
4130 SD=1:GOTO 5000
4200 '@@ araignœes @@
4210 LOCATE 6,1:PRINTCHR$(144+AA);:LOCATE 6,2:PRINTCHR$(145-AA);
4220 LOCATE 7,1:PRINTCHR$(145-AA);:LOCATE 7,2:PRINTCHR$(144+AA);
4225 TE=TE+1
4230 IF TE=3 THEN TE=0:BEEP RND(1)*10,1:IF AA=0 THEN AA=1 ELSE IF AA=1 THEN AA=0
4290 RETURN
4300 '@@ fosse @@
4310 GOSUB 4370:RETURN
4320 CA=0
4321 BEEP(RND(1)*10),1:GOSUB 4370
4322 IF INKEY$="" THEN 4321 ELSE 4325
4325 IF((-M+(12+(M*LI)))=15 AND X=12) THEN 4330
4326 GOTO 4395
4330 IF X<15 THEN X=16:CA=-1 ELSE X=11:CA=1
4340 LOCATE 12+((M*LI)-M),2:PRINTCHR$(149+CA);:CA=-CA:GOTO 1520
4370 LOCATE 12,1:PRINT"    ";:LOCATE 12,2:PRINT"    ";
4375 LOCATE 12+(M*LI),1:PRINTCHR$(145);:LOCATE 12+(M*LI),2:PRINTCHR$(149+CA);
4380 LI=LI+1:CA=-CA:IF(M*LI)>2 OR(M*LI)<1 THEN LI=-LI:M=-M
4390 RETURN
4395 LOCATE 12,2:PRINT"    ";:GOTO 5000
4400 '@@ serpent @@
4405 LOCATE 15+SE,2:PRINTCHR$(132)+" ";:SE=SE-1
4406 LOCATE 4-SE,2:PRINT" "+CHR$(133);:FOR I=1 TO 5:NEXT I
4410 IF SE=-10 THEN SE=0:LOCATE 6,2:PRINT" ";
4420 IF ID=1 AND ET=0 AND X<16 THEN 4430 ELSE 4490
4425 IF X>16 THEN 4490
4430 LOCATE 18-BO,1:PRINT"  ";:LOCATE 18-BO,2:PRINT"  ";
4440 BO=BO+1:CIRCLE((18-BO)*6+6,18),5
4490 RETURN
4500 '@@ descente @@
4505 IF X=10 THEN 8200
4510 LOCATE 10,0:PRINTCHR$(145);:LOCATE 10,1:PRINTCHR$(145);
4520 LOCATE 0,1:PRINTCHR$(225);:LOCATE 0,2:PRINTCHR$(140);
4530 LOCATE 1,2:PRINTCHR$(225);
4900 RETURN
5000 '============
5001 '=== mort ===
5002 '============
5003 '
5010 FOR M=45 TO 35 STEP-1:BEEP M,1:NEXT M
5100 IF SCREEN(X,3)=32 THEN LOCATE X,3:PRINTCHR$(147); ELSE LOCATE X,2:PRINTCHR$(147);
5200 MO$="GAME OVER"
5210 FOR I=1 TO 4:LOCATE 6,1:PRINTLEFT$(MO$,I);:BEEP I,1
5220 LOCATE 12,1:PRINTRIGHT$(MO$,I);:BEEP I+4,2:NEXT I
5500 GOSUB 9000
5800 IF INKEY$<>"E" THEN 5800 ELSE RUN 15
6000 '============
6001 '=caractšres=
6002 '=present...=
6128 FONT$(128)="0,0,0,12,124,124,252,252"
6129 FONT$(129)="0,0,0,252,252,248,248,192"
6130 FONT$(130)="0,0,0,0,48,112,112,240"
6131 FONT$(131)="0,0,0,0,116,116,100,228"
6132 FONT$(132)="0,0,0,0,248,252,204,204"
6133 FONT$(133)="0,0,0,0,28,28,184,184"
6134 FONT$(134)="0,0,0,0,28,60,124,120"
6135 FONT$(135)="0,0,0,0,0,112,116,116"
6136 FONT$(136)="0,0,0,0,228,196,204,156"
6137 FONT$(137)="0,0,0,0,196,196,192,128"
6138 FONT$(138)="0,0,0,252,252,252,228,236"
6139 FONT$(139)="0,0,0,0,112,248,156,28"
6140 FONT$(140)="0,0,0,0,64,200,216,240"
6141 FONT$(141)="0,0,0,0,64,200,216,240"
6142 FONT$(142)="0,0,0,0,192,192,128,0"
6143 FONT$(143)="60,60,124,124,124,248,248,248"
6144 FONT$(144)="192,132,132,12,12,28,28,60"
6145 FONT$(145)="240,244,252,252,252,124,124,60"
6146 FONT$(146)="204,204,204,156,156,28,60,60"
6147 FONT$(147)="140,140,24,24,48,244,224,128"
6148 FONT$(148)="48,116,108,252,248,240,112,0"
6149 FONT$(149)="216,152,244,252,60,48,0,0"
6150 FONT$(150)="252,252,252,188,140,0,0,0"
6224 FONT$(224)="180,252,252,204,140,0,4,4"
6225 FONT$(225)="128,132,4,12,12,252,252,248"
6226 FONT$(226)="236,204,204,132,128,0,0,0"
6227 FONT$(227)="28,60,252,216,0,0,0,0"
6228 FONT$(228)="244,244,108,108,0,0,0,0"
6229 FONT$(229)="236,132,236,220,0,0,0,0"
6230 FONT$(230)="128,192,192,128,0,0,0,0"
6231 FONT$(231)="4,4,4,12,12,12,60,124"
6232 FONT$(232)="240,240,240,224,224,248,248,240"
6233 FONT$(233)="56,120,120,224,0,0,0,0"
6234 FONT$(234)="60,48,0,0,0,0,0,0"
6235 FONT$(235)="120,0,0,0,0,0,0,0"
6236 FONT$(236)="124,248,0,0,0,0,0,0"
6237 FONT$(237)="240,0,0,0,0,0,0,0"
6500 '=========
6501 '=present=
6502 '=========
6510 CLS
6515 LOCATE 4,0
6520 FOR I=128 TO 142
6530 PRINTCHR$(I);
6540 NEXT
6550 LOCATE 4,1:FOR I=143 TO 150:PRINTCHR$(I);:NEXT
6560 FOR I=224 TO 230:PRINTCHR$(I);:NEXT
6570 LOCATE 3,2:FOR I=231 TO 235:PRINTCHR$(I);:NEXT
6580 LOCATE 3,3:PRINTCHR$(236);CHR$(237);
6590 LINE(78,16)-(81,16)
6600 LOCATE 0,0
6610 LINE(105,14)-(107,14):LINE(106,14)-(106,17)
6620 LINE(109,14)-(109,17):LINE(113,14)-(113,17):PSET(110,15):PSET(112,15)
6630 PSET(111,16)
6640 LINE(1,1)-(118,1):LINE-(118,30):LINE-(1,30):LINE-(1,1)
6650 LINE(80,25)-(80,28):PSET(81,25):PSET(81,28)
6660 PSET(83,28)
6670 LINE(88,24)-(88,28):PSET(89,24):PSET(89,26):PSET(89,28)
6680 PSET(90,25):PSET(90,27)
6690 PSET(92,25):PSET(92,27):PSET(92,28):LINE(93,25)-(93,28)
6692 LINE(95,25)-(95,28):PSET(96,28):LINE(97,25)-(97,28)
6694 PSET(99,27):PSET(99,28):LINE(100,25)-(100,28)
6696 LINE(102,25)-(102,28):PSET(103,25):PSET(103,26):PSET(103,28)
6698 LINE(105,25)-(107,25):LINE(106,25)-(106,28)
6700 '=========
6701 '=musique=
6702 '=========
6703 '* copyright *
6704 '** sciacco **
6705 '**stœphane**
6710 RESTORE 6800
6720 FOR I=1 TO 35:READ A,B:BEEP A,B:NEXT I
6785 BEEP 0,10:BEEP 0,10
6790 RETURN
6800 DATA 10,6,11,4,13,4,18,10,10,6,11,4,13,10,10,6,11,4,13,4,20,10
6810 DATA 10,6,11,4,13,4,22,6,20,8,10,6,11,4,13,4,18,7,20,7,22,6,23,8
6820 DATA 13,6,13,6,22,8,20,6,13,6,22,8,20,6,13,6,23,8
6830 DATA 22,8,20,8,18,12
7000 '=======
7001 '=gagne=
7002 '=======
7005 CLS
7006 TMP$=TIME$
7090 FOR I=0 TO 10
7100 LINE(1+I,30-I)-(118-I,1+I):LINE-(118-I,30-I)
7105 BEEP I,1
7110 LINE-(1+I,30-I):LINE-(1+I,1+I):BEEP 1,I:NEXT I
7200 LOCATE 3,1:PRINT" Very  good !!";
7830 GOSUB 6700:CLS:GOSUB 9000:LOCATE 0,0
7850 LOCATE 4,0:PRINT"Votre temps:";:LOCATE 6,1:PRINTTMP$
7870 END
8000 '=========
8001 'œtage inf
8002 '=========
8100 'descente
8105 AD=T:DA=0:ET=1
8110 GOSUB 8500:GOSUB 8510:GOSUB 8570:GOSUB 8500:GOSUB 8520:GOSUB 8570:GOSUB 8530
8120 GOSUB 8540:GOSUB 8550:GOSUB 8570:GOSUB 8540:GOSUB 8560:GOSUB 8570:X=X+1:GOTO 1520
8200 'montœe
8205 DA=AD:LOCATE 10,2:PRINT" ";
8210 GOSUB 8540:GOSUB 8560:GOSUB 8570:GOSUB 8540:GOSUB 8550:GOSUB 8570:GOSUB 8530
8220 GOSUB 8500:GOSUB 8520:GOSUB 8570:GOSUB 8500:GOSUB 8510:GOSUB 8570:ET=0:X=X-1
8230 LOCATE 10,1:PRINT" ";:LOCATE 10,2:PRINT" ";:LOCATE 10,3:PRINT" ";:GOTO 1520
8500 LOCATE 10,1:PRINTCHR$(145);:LOCATE 10,2:PRINTCHR$(145);
8505 LOCATE 10,3:PRINTCHR$(145);:RETURN
8510 LOCATE 10,2:PRINTCHR$(143);:RETURN
8520 LOCATE 10,3:PRINTCHR$(143);:RETURN
8530 CLS:PRINTP$;:LOCATE 0,3:T=DA:PRINTSOL$(T);
8535 FOR I=1 TO 6:LINE(113+I,24)-(113+I,31):NEXT I:RETURN
8540 LOCATE 10,0:PRINTCHR$(145);:LOCATE 10,1:PRINTCHR$(145);:RETURN
8550 LOCATE 10,0:PRINTCHR$(143);:RETURN
8560 LOCATE 10,1:PRINTCHR$(143);:RETURN
8570 BEEP 4,1:FOR EMT=0 TO 30:NEXT EMT:RETURN
9000 '==========
9001 '=  score =
9002 '==========
9010 FOR I=0 TO 7
9020 LOCATE I,3:PRINT" SCORE:";SC;
9030 BEEP I*4,I:NEXT I
9040 RETURN
Avatar du membre
Joscelyn
Fonctionne à 1200 bauds
Fonctionne à 1200 bauds
Messages : 811
Enregistré le : 10 juin 2012 01:19
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par Joscelyn »

phm a écrit : 06 déc. 2021 18:09 Ledudu, j'aimerai bien voir ce que cela donne sur écran :D
+1 :slime:
ImageImageImage ■■■ Image
Je cherche : lecteur 3,5" 720Ko / lecteur 5,25" 360Ko / Lecteur Casio FP-1021FD1 et une Casio FX-81 --> trouvée ! Thanks, Andrew :D
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

Salut,
Je n'arrive pas à afficher les font$ (caractères redéfinis) sur l'écran via le X-720.
J'ai essayé un peu tous les SCREEN mode,X,Y
A suivre demain
Avatar du membre
jvernet
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 7958
Enregistré le : 24 mai 2002 09:57
Localisation : France 69
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par jvernet »

Je pense que le X720 ne peut pas du tout faire tourner ce programme. Deja justement parceque les fonctions de redefinitions des caractères ne marchent pas dessus.
"l'ordinateur et l'homme sont les deux opposés les plus intégraux qui existent. L'homme est lent, peu rigoureux et très intuitif. L'ordinateur est super rapide, très rigoureux et complètement con."
remy
Fonctionne à 2400 bauds
Fonctionne à 2400 bauds
Messages : 2218
Enregistré le : 13 mars 2006 15:39
Localisation : Issy
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par remy »

Oui, les fonts, le LCD et les fonctions graphiques sont gérées par le coprocesseur dédié et non par le Z80 (c'est bien le point faible du X-07 à mon avis). Le X-720 n'a donc que peu de chance de savoir gérer les caractères spéciaux.
Peux être y a t il dans la ROM du X-720 une instruction BASIC équivalente.
A investiguer...

edit: Eh bien c'est ce que je viens de faire. Page 49 de la doc ils expliquent qu'en sélectionnant le 3eme jeu de caractère on accède au font défini par FONT$ . Cela correspond au mode LCD. RTFM :D
PockEmul, Emulateur de pocket Sharp, Canon, Casio, HP, TI, NEC, Panasonic, Sanco, Seiko, General, National, ....
sur Windows, Linux, OS X et Android
Available now on the Google Play Store and the Apple Store
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

Salut Rémy, jvernet,

Merci pour vos réponses.

Oui j'ai sorti le manuel, surtout les pages 21-25, je n'avais pas lu la page 49. Tout se pilote par l'instruction SCREEN x,y,z.

J'avoue que je suis un peu perplexe quand je lis page 49 qu'avec le mode LCD (=écran X-07 ?) on peut obtenir les caractères spéciaux sur l'écran du téléviseur ou du moniteur. C'est donc possible ?
Page 23, il est écrit qu'en mode 3 (premier paramètre x de l'instruction SCREEN) : "Les caractères peuvent être récrits". Même chose en mode 4 et 5.

J'ai essayé pas mal de combinaisons de paramètres SCREEN sans succès. Ce n'est donc pas possible ?

De ton côté, Remy, je ne comprends pas bien à quelle conclusion tu arrives dans ton message précédent.
Ce serait possible ou pas ?

ledudu
remy
Fonctionne à 2400 bauds
Fonctionne à 2400 bauds
Messages : 2218
Enregistré le : 13 mars 2006 15:39
Localisation : Issy
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par remy »

Je crois que c'est clair :
"En LCD on peut obtenir l'affichage sur l'écran du téléviseur ou du moniteur des caractères définis par l'utilisateur à l'ide de la fonction FONT$"

Donc avec un SCREEN 3,2,2
et un POKE &H15,1
ça va marcher
PockEmul, Emulateur de pocket Sharp, Canon, Casio, HP, TI, NEC, Panasonic, Sanco, Seiko, General, National, ....
sur Windows, Linux, OS X et Android
Available now on the Google Play Store and the Apple Store
Avatar du membre
ledudu
Fonctionne à 14400 bauds
Fonctionne à 14400 bauds
Messages : 5631
Enregistré le : 26 mars 2009 13:07
Localisation : Ile de France
Contact :

Re: A "Indiana Jones" sur Canon X-07

Message par ledudu »

Quel farceur !

On vient de le tester, d'où le ton un peu péremptoire du gars. :D :D

Bien joué Rémy :wink:
On ne voit pas que tu as édité ton message...
Modifié en dernier par ledudu le 07 déc. 2021 13:21, modifié 1 fois.
Répondre

Retourner vers « A quoi t'as joué hier ? »